/**
   PROTOCOLOS DE COMUNICACIÓN EN IOT Y TRANSMISIÓN DE DATOS

   - Delgado Alvaro
   - Loayza Jonathan
   - Pernia Javier
   - Sarmiento Christian
   
  III. Creación de Cuenta y Transmisión de Datos a Adafruit.io
*/

// Agregamos las librerías a usar
#include <WiFi.h>
#include <PubSubClient.h>
#include "DHTesp.h"
#include <ESP32Servo.h>

// Establecemos la comunicación WiFi
const char* ssid ="Wokwi-GUEST";
const char* password = "";

// Inicializamos el broker MQTT disponible para uso
const char* mqtt_server = "io.adafruit.com";
const char* mqtt_username = "Jplr1992";
const char* mqtt_password = "aio_veIP37BkLb6jhwX9VvPJc3cAUPP6";

// Generamos los tópicos a usar
const char* SUBTOPIC_LED = "Jplr1992/f/LED";
const char* SUBTOPIC_DOOR = "Jplr1992/f/SERVO";
const char* SUBTOPIC_TEMP = "Jplr1992/f/Temp";
const char* SUBTOPIC_HUMIDITY = "Jplr1992/f/Humid";

WiFiClient espClient;
PubSubClient client(espClient);

// Configuramos los pines del esp32 
// LED
const int LED_PIN = 13;

// DHT
const int DHT_PIN = 15;
DHTesp dhtSensor;

// Servo
Servo servo;  

int SERVO_PIN = 2;  

//Inicializamos la conexión a internet 
void setup_wifi() {
  delay(10);
  Serial.print("Conectando a ");
  Serial.println(ssid);

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi conectado");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
}

//Inicializamos la conexión al broker MQTT 
void reconnect() {
  while (!client.connected()) {
    Serial.println("Intentado conexión MQTT ...");
    String clientId = "esp32-dht22-clientId-";
    clientId += String(random(0xffff), HEX);
    if (client.connect(clientId.c_str(),mqtt_username,mqtt_password)) {
      Serial.println("Conectado");
      client.subscribe(SUBTOPIC_LED);
      client.subscribe(SUBTOPIC_DOOR);
      Serial.println("Topicos Suscritos");
    } else {
      Serial.print("Conexión fallida");
      Serial.print(client.state());
      Serial.println(" Intente en 5 segundos");
      delay(5000);
    }
  }
}

//Inicializamos la publicación de nuestros tópicos
void callback(char *topic, byte *payload, unsigned int length) {
  Serial.print("Topicos recibidos: ");
  Serial.println(topic);

  Serial.print("Payload: ");
  String data = "";
  for (int i = 0; i < length; i++) {
    data += (char)payload[i]; 
  }
  Serial.println(data);
  Serial.print("Tamaño de mensaje: ");
  Serial.println(length);
  
  // Lectura del tópico LED
  if (String(topic) == "Jplr1992/f/LED") {
   if (data =="ON") {
     Serial.print("Status LED: ");
     Serial.println(data);
     Serial.println("");
     digitalWrite(LED_PIN, HIGH);
   }
   else {
     digitalWrite(LED_PIN, LOW);
   }
  }

  // Lectura del tópico SERVO
  else if (String(topic) == "Jplr1992/f/SERVO") {
    int degree = data.toInt(); // Convert the received data to an integer
    Serial.print("Moviendo servo a grados: ");
    Serial.println(degree);
    Serial.println("");
    servo.write(degree); // Move the servo to the specified degree
  }

}

//Inicializamos las configuraciones básicas del programa
void setup() {
  Serial.begin(115200);
  randomSeed(micros());

  pinMode(LED_PIN, OUTPUT);

  dhtSensor.setup(DHT_PIN, DHTesp::DHT22);

  servo.attach(SERVO_PIN, 500, 2400);  // attaches the servo on pin 13 to the servo object
  
  servo.write(0);

  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
}

float old_temperature = 0;
float old_humidity = 0;

//Generamos bucle que publique la temperatura y humedad cuando su valor es actualizado
void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  TempAndHumidity  data = dhtSensor.getTempAndHumidity();
  float temperature = data.temperature;
  float humidity = data.humidity;

  if (old_temperature != temperature) {
    client.publish(SUBTOPIC_TEMP, String(temperature, 2).c_str());
  }
  old_temperature = temperature;

  if (old_humidity != humidity) {
    client.publish(SUBTOPIC_HUMIDITY, String(humidity, 1).c_str());
  }
  old_humidity = humidity;

  delay(1000);
}