// https://github.com/rmorenojr/ElegooTutorial/blob/master/Lesson%2028%20-%204%20Digit%207%20Segment%20Display/4_digit_proper_bb.png

const int dataPin  = 12;  // 74HC595 pin 8 DS
const int latchPin = 11;  // 74HC595 pin 9 STCP
const int clockPin = 9;   // 74HC595 pin 10 SHCP
const int digit0   = 7;   // 7-Segment pin D4
const int digit1   = 6;   // 7-Segment pin D3
const int digit2   = 5;   // 7-Segment pin D2
const int digit3   = 4;   // 7-Segment pin D1

byte table[] =
{ 0x5F,  // = 0
  0x44,  // = 1
  0x9D,  // = 2
  0xD5,  // = 3
  0xC6,  // = 4
  0xD3,  // = 5
  0xDB,  // = 6
  0x45,  // = 7
  0xDF,  // = 8
  0xC7,  // = 9
  0xCF,  // = A
  0xDA,  // = b
  0x1B,  // = C
  0xDC,  // = d
  0x9B,  // = E
  0x8B,  // = F
  0x00   // blank
};
byte digitDP = 32;
byte controlDigits[] = { digit0, digit1, digit2, digit3 };
byte displayDigits[] = { 0, 0, 0, 0, 0 };
unsigned long onTime = 0;
bool switchView = false;
unsigned int counter = 0;
int digitDelay = 50;
int brightness = 90;
unsigned int ShowSegCount = 250;
//bool commonCathode = true;

void setup() {
  //DDRD = 0xff;
  //DDRB = 0xff;
  //PORTD = 0xf0;

  pinMode(latchPin, OUTPUT);
  pinMode(clockPin, OUTPUT);
  pinMode(dataPin, OUTPUT);

  for (int x = 0; x < 4; x++) {
    pinMode(controlDigits[x], OUTPUT);
    digitalWrite(controlDigits[x], LOW);
  }
}

void DisplaySegments() {
  for (int x = 0; x < 4; x++) {
    for (int j = 0; j < 4; j++) {
      digitalWrite(controlDigits[j], LOW);
    }
    digitalWrite(latchPin, LOW);
    if (bitRead(displayDigits[4], x) == 1) {
      shiftOut(dataPin, clockPin, MSBFIRST, displayDigits[x]);
    } else {
      shiftOut(dataPin, clockPin, MSBFIRST, table[displayDigits[x]]);
    }

    digitalWrite(latchPin, HIGH);
    digitalWrite(controlDigits[x], HIGH);
    delay(1);
  }
  for (int j = 0; j < 4; j++) {
    digitalWrite(controlDigits[j], LOW);
  }
}

void HexCounter() {
  byte Letter = B00011011;
  bool incrementValue = true;
  for (int d = 0; d < 3; d++) {
    int x = int(displayDigits[d]);
    if (incrementValue == true) {
      x++;
      incrementValue = false;
      if (x > 15) {
        displayDigits[d] = 0;
        incrementValue = true;
      } else {
        displayDigits[d] = byte(x);
      }
    }
  }
  displayDigits[3] = Letter;
  displayDigits[4] = B1000;

  if ((displayDigits[0] == 0) && (displayDigits[1] == 0) && (displayDigits[2] == 0)) {
    switchView = !switchView;
    for (int x = 0; x < 5; x++) {
      displayDigits[x] = 0;
    }
    displayDigits[4] = B0000;
  }
}

void RawDisplay() {

  displayDigits[0] = B01011111;  // 0
  displayDigits[1] = B00011010;  // L
  displayDigits[2] = B11001111;  // A
  displayDigits[3] = B11001110;  // H
  displayDigits[4] = B1111;

  if (counter < ShowSegCount) {
    counter++;
  } else {
    counter = 0;
    switchView = !switchView;
    for (int x = 0; x < 5; x++) {
      displayDigits[x] = 0;
    }
    displayDigits[4] = B0000;
  }
}

void loop() {
  DisplaySegments();
  delayMicroseconds(1638 * ((100 - brightness) / 10));
  unsigned long nowValue = millis() - onTime;
  if (nowValue >= long(digitDelay)) {
    onTime = millis();
    if (switchView == true) {
      RawDisplay();
    } else {
      HexCounter();
    }
  }
}