#include <EspMQTTClient.h>
#include <WiFi.h>
#include <DHT.h>
#include <PubSubClient.h>

#define WIFI_NAME "Wokwi-GUEST"           // YOUR_WIFI_NAME
#define WIFI_PASSWORD ""   // YOUR_WIFI_PASSWORD
#define MQTT_USERNAME "NgCongChinh"   // YOUR_MQTT_USERNAME 
#define MQTT_PASSWORD "13505"   // YOUR_MQTT_PASSWORD
#define MQTT_CLIENT_ID "nc493ed35elvwpszvipg" // YOUR_MQTT_CLIENT_ID 

EspMQTTClient client(
  WIFI_NAME,
  WIFI_PASSWORD,
  "thingsboard.cloud",  // MQTT Broker server ip
  MQTT_USERNAME,
  MQTT_PASSWORD,
  MQTT_CLIENT_ID
);

// DHT information
#define DHTPIN 5
#define DHTTYPE DHT22       // or set DHT11 type if you use DHT11
DHT dht(DHTPIN, DHTTYPE);

unsigned long lastTime = 0;
unsigned long delayTime = 1000; // set a period of sending data.

void setup() {
  Serial.begin(115200);

  // Begin DHT
  dht.begin();
}

void onConnectionEstablished() {
  Serial.println("MQTT Client is connected to ThingsBoard!");
}

void publishData() {
  if (client.isConnected() && (millis() - lastTime > delayTime)) {
    float h = dht.readHumidity();
    // Read temperature as Celsius (the default)
    float t = dht.readTemperature();
  
    // Check if any reads failed and exit early (to try again).
    if (isnan(h) || isnan(t)) {
      Serial.println(F("Failed to read from DHT sensor!"));
      return;
    }
    Serial.print(F("\nTemperature: "));
    Serial.print(t);
    Serial.print(F("°C "));
    Serial.print(F("Humidity: "));
    Serial.print(h);
    Serial.println(F("%  "));

    Serial.println(F("\nPublising data to ThingsBoard"));
    
    String MY_TOPIC = "v1/devices/me/telemetry";  // build your topic: v1/devices/me/telemetry
    String payload = "{\"temperature\":" + String(t) + ",\"humidity\":" + String(h) + "}";  // build your payload: {"temperature":<value1>,"humidity":<value2>}
    client.publish(MY_TOPIC, payload);

    Serial.println("Data published");
    lastTime = millis();
  }
}

void loop() {
  client.loop();
  publishData();
}