/*
Чтобы это дерьмо работало с несколькими датчиками на одной шине нужно в описании датчика правильно указать его адрес
пример
физический адрес датчика          0x28,0xFF,0xF1,0x74,0x16,0x20,0x8F,0x2D
адрес для описания в diagram.json           0xF1,0x74,0x16,0x20,0x8F,0x2D
{
      "type": "board-ds18b20",
      "id": "temp1",
      "top": -87.53,
      "left": 109.68,
      "attrs": { "deviceID": "F17416208F2D" }
    },
!!!На этих библах при отвале датчика индексы сьезжают
*/


//Three sensors, one bus, LCD by TIM
#include <OneWire.h>
#include <DallasTemperature.h>
#include <LiquidCrystal_I2C.h>

const byte I2C_ADDR = 0x27;
const byte LCD_COLUMNS = 20;
const byte LCD_LINES= 4;

LiquidCrystal_I2C lcd(I2C_ADDR, LCD_COLUMNS, LCD_LINES);

// Connect DS18B29 to Arduino pin D12.
const byte ONE_WIRE_BUS = 12;

// Setup a OneWire instance to communicate with any OneWire devices.
OneWire oneWire(ONE_WIRE_BUS);

// Pass our OneWire reference to Dallas Temperature sensor.
DallasTemperature sensors(&oneWire);

 byte numDevices = 0;

// Initialization of sensor and serial communication.
void setup()
{
  Serial.begin(115200);

  lcd.init();
  lcd.backlight();
  lcd.setCursor(0, 0);
  lcd.print("Temperatures:");
  sensors.begin();

  byte address[8];

  while (oneWire.search(address))
  {
    Serial.print("Bus index=");
    Serial.print(numDevices);
    Serial.print(";  Device address=\t");
    for(byte i = 0; i < 8; i++)
    {
      Serial.print("0x");
      Serial.print(address[i], HEX);
      Serial.print("\t");
    }
    Serial.println("");
    Serial.print("\t\t\t\t");
    for(byte i = 0; i < 8; i++)
    {
      Serial.print(address[i], BIN);
      Serial.print("\t");
    }
    Serial.println();
    numDevices++;
  }
}

const byte LCD_BUFFER_LENGTH = 20;
char lcdBuffer[LCD_BUFFER_LENGTH];  // One extra for NULL terminator.
const char LCD_BUFFER_FORMAT[] = "  %d: %s\xDF\x43            ";  // Escape the two characters for °C because DF merges in to C as a valid hex number.

void loop()
{
  if (numDevices > 0)
  {
    sensors.requestTemperatures();

    for (byte i = 0; i < numDevices; i++)
    {
      float temperatureCelsius = sensors.getTempCByIndex(i);
      int tInt = int(temperatureCelsius);

      Serial.print("Bus index=");
      Serial.print(i);
      Serial.print(";  Temperature=");
      Serial.print(temperatureCelsius);
      Serial.println("°C");

      char floatBuffer[20];
      snprintf(lcdBuffer, LCD_BUFFER_LENGTH, LCD_BUFFER_FORMAT, i, dtostrf(temperatureCelsius, 8, 3, floatBuffer));
      lcd.setCursor(0, i + 1);
      lcd.print(lcdBuffer);
    }
  }

  delay(1000);
}