#include <WiFi.h>
#include <PubSubClient.h>
#include <Adafruit_Sensor.h>
#include <DHT.h>
#include <Wire.h>
#include <Adafruit_TSL2591.h>

const int PIR_PIN = 26;    // PIR sensor pin
const int BUZZER_PIN = 5;  // Buzzer pin
const int DHT_PIN = 14;    // DHT11 sensor pin
const int LDR_PIN = 33;    // LDR sensor pin
const int GAS_SENSOR_PIN = 34;  // Analog pin for the gas sensor

const char* ssid = "Wokwi-GUEST";      // WiFi SSID
const char* password = "";
const char* mqtt_server = "broker.emqx.io";  // MQTT server URL

WiFiClient espClient;
PubSubClient client(espClient);
unsigned long lastMsg = 0;

DHT dht(DHT_PIN, DHT11);
Adafruit_TSL2591 tsl = Adafruit_TSL2591(2591);

void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  randomSeed(micros());

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    String clientId = "ESP32Client-";
    clientId += String(random(0xffff), HEX);
    if (client.connect(clientId.c_str())) {
      Serial.println("Connected");
      client.publish("/ThinkIOT/Publish", "Welcome");
      client.subscribe("/ThinkIOT/Subscribe");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void setup() {
  pinMode(PIR_PIN, INPUT);    // PIR sensor pin as input
  pinMode(BUZZER_PIN, OUTPUT);  // Buzzer pin as output

  Serial.begin(115200);
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);

  dht.begin();
  tsl.begin();
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  unsigned long now = millis();
  if (now - lastMsg > 2000) {
    lastMsg = now;

    int motionStatus = digitalRead(PIR_PIN);
    float humidity = dht.readHumidity();
    float temperature = dht.readTemperature();

    // Check if the temperature reading is valid
    if (!isnan(temperature)) {
      if (temperature < -40.0 || temperature > 80.0) {
        Serial.println("Invalid temperature reading. Check the sensor or wiring.");
        temperature = 0.0; // Set a default value
      }
    } else {
      Serial.println("Failed to read temperature from DHT sensor. Check the sensor or wiring.");
      temperature = 0.0; // Set a default value
    }

    uint16_t ldrValue = tsl.getFullLuminosity();

    if (motionStatus == HIGH) {
      // Motion detected
      tone(BUZZER_PIN, 1000); // Turn on the buzzer
      delay(1000); // Buzzer on for 1 second
      noTone(BUZZER_PIN); // Turn off the buzzer

      client.publish("/Thinkitive/motion", "Motion Detected"); // Publish motion topic
      Serial.println("Motion Detected- Someone at the Door");
    }

    int gasValue = analogRead(GAS_SENSOR_PIN);

    String motionStatusStr = String(motionStatus);
    client.publish("/Thinkitive/motionStatus", motionStatusStr.c_str());  // Publish motion status topic

    String temperatureStr = String(temperature);
    String humidityStr = String(humidity);
    client.publish("/Thinkitive/temperature", temperatureStr.c_str());  // Publish temperature topic
    client.publish("/Thinkitive/humidity", humidityStr.c_str());  // Publish humidity topic

    String ldrValueStr = String(ldrValue);
    client.publish("/Thinkitive/ldrValue", ldrValueStr.c_str());  // Publish LDR value topic

    String gasValueStr = String(gasValue);
    client.publish("/Thinkitive/gasValue", gasValueStr.c_str());  // Publish gas value topic

    Serial.print("Motion Status: ");
    Serial.println(motionStatus);
    Serial.print("Temperature: ");
    Serial.println(temperature);
    Serial.print("Humidity: ");
    Serial.println(humidity);
    Serial.print("LDR Value: ");
    Serial.println(ldrValue);
    Serial.print("Gas Sensor Value: ");
    Serial.println(gasValue);
  }
}