// https://www.emqx.com/en/blog/esp32-connects-to-the-free-public-mqtt-broker
// all credentials for the public MQTT-Server emqx
// mqttx - gui client for subscribing to mqtt server

#include <WiFi.h>
#include <Arduino.h>
#include <PubSubClient.h>
#include <NTPClient.h>
// #include <WiFiUdp.h>


// Set your Static IP address - place outside loop() / setup()
IPAddress local_IP(10, 10, 0, 2);
IPAddress gateway(10, 10, 0, 138);
IPAddress subnet(255, 255, 255, 0);
IPAddress primaryDNS(8, 8, 8, 8);       // optional
IPAddress secondaryDNS(8, 8, 4, 4);     // optional


const char* ssid = "Wokwi-GUEST";
const char* password = "";

const char* mqtt_server = "broker.emqx.io"; // eg. your-demo.cedalo.cloud or 192.168.1.11
const uint16_t mqtt_server_port = 1883;     // or 8883 most common for tls transport
const char* mqttUser = "emqx";
const char* mqttPassword = "public";
const char* mqttTopicIn = "emqx/esp32";
const char* mqttTopicOut = "emqx/esp32";

String mqttmsg = "";

WiFiClient client; 
PubSubClient mqttClient(client);

WiFiUDP ntpUDP;
NTPClient timeClient(ntpUDP);



//--------------------------------------
// function setup_wifi called once
//--------------------------------------
void setup_wifi() {

  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);


  // // ------  Configures static IP address
  // WiFi.mode(WIFI_STA);
  // // while (!WiFi.config(local_IP, gateway, subnet, primaryDNS, secondaryDNS)) {
  //  WiFi.config(local_IP, gateway, subnet);


  // ----- Standard-Mode to connect to Wifi / WLAN
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  timeClient.begin();
  Serial.println("WiFi connected");
}



//--------------------------------------
// function callback called everytime 
// if a mqtt message arrives from the broker
//--------------------------------------
void callback(char* topic, byte* payload, unsigned int length) {
  mqttmsg = "";
  Serial.print("Message arrived on topic: '");
  Serial.print(topic);
  Serial.print("' with payload: ");
  for (unsigned int i = 0; i < length; i++) {
    // Serial.print((char)payload[i]);
    mqttmsg += (char)payload[i];
  }
  Serial.println(mqttmsg);
  Serial.println();

}

//--------------------------------------
// function connect called to (re)connect
// to the broker
//--------------------------------------
void connect() {
  while (!mqttClient.connected()) {
    Serial.print("Attempting MQTT connection...");
    String mqttClientId = "_esp32_-";              // String mqttClientId = "";
    mqttClientId += String(WiFi.macAddress());     // this 2 lines are optional
    Serial.printf("The client %s connects to the public MQTT broker ", mqttClientId.c_str());
    Serial.printf ("Got IP: %s ", WiFi.localIP().toString());

    if (mqttClient.connect(mqttClientId.c_str(), mqttUser, mqttPassword)) {
      Serial.println("- connected");
      mqttClient.subscribe(mqttTopicIn);
    } else {
      Serial.print("failed, rc=");
      Serial.print(mqttClient.state());
      Serial.println(" will try again in 5 seconds");
      delay(5000);
    }
  }
}

//--------------------------------------
// main arduino setup fuction called once
//--------------------------------------
void setup() {
  Serial.begin(115200);
  setup_wifi();
  mqttClient.setServer(mqtt_server, mqtt_server_port);
  mqttClient.setCallback(callback);
}


//--------------------------------------
// main arduino loop fuction called periodically
//--------------------------------------
void loop() {
  if (!mqttClient.connected()) {
    connect();
  }

  String myCurrentTime = timeClient.getFormattedTime();
  mqttClient.publish(mqttTopicOut,("ESP32: Mqtt is awesome. Time: " + myCurrentTime).c_str());
  Serial.println();
  
  delay (3000);
  mqttClient.loop();
  timeClient.update();
}