#include <Toggle.h>

const byte ldrPins[] = {3, 4, 5};
const byte nbLdr = sizeof ldrPins / sizeof * ldrPins;
const byte ldrLowPitches[nbLdr] = {10, 15, 20};
const byte ldrHighPitches[nbLdr] = {100, 150, 200};
bool lastLdrState[nbLdr];
Toggle HighSwitch;
bool highPitchActif = false;

void noteOn(byte pitch) {
  Serial.print("ON - "); Serial.println(pitch);
}

void noteOff(byte pitch) {
  Serial.print("OFF - "); Serial.println(pitch);
}

void setup() {
  HighSwitch.begin(A0);

  Serial.begin(115200);
  for (byte i = 0; i < nbLdr; i++) {
    pinMode(ldrPins[i], INPUT_PULLUP);
    lastLdrState[i] = (digitalRead(ldrPins[i]) == LOW);
  }
}

void loop() {
  HighSwitch.poll();
  if (HighSwitch.onPress()) {
    highPitchActif = !highPitchActif;
    Serial.println("flipping Pitch");
  }

  for (byte i = 0; i < nbLdr; i++) {
    byte ldrState = (digitalRead(ldrPins[i]) == LOW);
    if (lastLdrState[i] != ldrState) {
      lastLdrState[i] = ldrState;
      if (ldrState) {
        noteOn(highPitchActif ? ldrHighPitches[i] : ldrLowPitches[i]);
      } else {
        noteOff(highPitchActif ? ldrHighPitches[i] : ldrLowPitches[i]);
      }
    }
  }
}