#include <WiFi.h>
#include <ESP32Servo.h>
#include "DHT.h"
#include <PubSubClient.h>

const int LEDLIVINGROOM = 32;
const int LEDBEDROOM = 33;
const int LEDSERVO = 25;
const int SERVO = 14;
#define SERVOCLOSE 80
#define SERVOOPEN 170


const int DHTPIN = 27;
const int DHTTYPE = DHT11;

const int TRIG_PIN = 22;
const int ECHO_PIN = 23;

#define WIFI_SSID "Wokwi-GUEST"
#define WIFI_PASSWORD ""
#define PORT_MQTT 1883

IPAddress server(192, 168, 1, 2);
WiFiClient wifiClient;
PubSubClient client(wifiClient);

Servo myServo;
DHT dht(DHTPIN, DHTTYPE);

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print(String(topic) + ": ");

  String dataString;
  for (int i = 0; i < length; i++)
    dataString += (char)payload[i];


  Serial.println(dataString);

  if (String(topic) == "lighting/LivingRoom") {
    bool data = dataString == "true";
    Serial.print("Lightning LivingRoom: ");
    Serial.println(data);
    digitalWrite(LEDLIVINGROOM, data);
    return;
  }

  if (String(topic) == "lighting/Bedroom") {
    int data = dataString.toInt();
    Serial.print("Lightning Bedroom: ");
    Serial.println(data);
    analogWrite(LEDBEDROOM, data);
    return;
  }

  if (String(topic) == "status/OpenDoor") {
    bool openDoor = dataString == "true";
    Serial.print("Door status: ");
    Serial.println(openDoor);
    if ((bool)openDoor) {
      if (myServo.read() >= SERVOCLOSE + 10)
        for (int i = SERVOCLOSE; i >= SERVOOPEN; i++) {
          myServo.write(i);
          delay(5);
        }
      else myServo.write(SERVOOPEN);


      // myServo.write(SERVOOPEN);
      digitalWrite(LEDSERVO, HIGH);
    } else {
      if (myServo.read() <= SERVOOPEN - 10)
        for (int i = SERVOOPEN; i <= SERVOCLOSE; i++) {
          myServo.write(i);
          delay(5);
        }
      else myServo.write(SERVOCLOSE);


      // myServo.write(SERVOCLOSE);
      digitalWrite(LEDSERVO, LOW);
    }

    return;
  }
}

void connect() {

  WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
  Serial.println("\nConnecting");

  while (WiFi.status() != WL_CONNECTED) {
    Serial.print(".");
    delay(100);
  }

  Serial.println();
  Serial.print("Connected to the WiFi network ");
  Serial.println(WiFi.localIP());
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    String clientId = "ESP32Client-" + String(random(0xffff), HEX);
    if (client.connect(clientId.c_str())) {
      Serial.println("connected");

      // Once connected, publish an announcement...
      client.subscribe("lighting/LivingRoom");
      client.subscribe("lighting/Bedroom");
      client.subscribe("status/OpenDoor");

      client.publish("code/renew", clientId.c_str());
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}

// Cycle time
unsigned long previousMillisUpdateTempHumd = 0;
const int intervalUpdateTempHumd = 2000;

unsigned long previousMillisUpdatePosition = 0;
const int intervalUpdatePosition = 500;

void setup() {
  Serial.begin(9600);
  while (!Serial)
    ;
  delay(1500);

  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);

  pinMode(LEDLIVINGROOM, OUTPUT);
  pinMode(LEDBEDROOM, OUTPUT);
  pinMode(LEDSERVO, OUTPUT);
  myServo.setPeriodHertz(50);
  myServo.attach(SERVO);
  myServo.write(SERVOCLOSE);

  dht.begin();

  client.setServer(server, PORT_MQTT);
  client.setCallback(callback);

  connect();
  // Allow the hardware to sort itself out

  previousMillisUpdateTempHumd = millis() - intervalUpdateTempHumd - 10;
  delay(1500);
}

int getDistance() {
  digitalWrite(TRIG_PIN, HIGH);
  delayMicroseconds(10);
  digitalWrite(TRIG_PIN, LOW);
  long duration = pulseIn(ECHO_PIN, HIGH);
  int distance = duration * 0.034 / 2;
  return distance;
}



void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  unsigned long currentMillis = millis();

  if (currentMillis - previousMillisUpdateTempHumd >= intervalUpdateTempHumd) {
    previousMillisUpdateTempHumd = currentMillis;
    float humidity = dht.readHumidity();
    float temperature = dht.readTemperature();

    char humidityString[8];
    dtostrf(humidity, 2, 2, humidityString);

    char temperatureString[8];
    dtostrf(temperature, 2, 2, temperatureString);

    client.publish("information/humidity", humidityString);
    client.publish("information/temperature", temperatureString);
    // Serial.println("Update Temperature & Humidity");
  }


  if (currentMillis - previousMillisUpdatePosition >= intervalUpdatePosition) {
    previousMillisUpdatePosition = currentMillis;
    int distance = getDistance();
    // Serial.println(distance);
    client.publish("status/distance", String(distance).c_str());
  }
}