#include <WiFi.h>
#include "PubSubClient.h"
#include <DHT.h>
#include <LiquidCrystal_I2C.h>
#include  <Wire.h>
LiquidCrystal_I2C lcd(0x27,  16, 2);

#define DHTPIN 4
#define DHTTYPE DHT22 
DHT dht(DHTPIN, DHTTYPE);


const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqttServer = "broker.emqx.io";
int port = 1883;


WiFiClient espClient;
PubSubClient client(espClient);

void setup() {
  Serial.begin(115200);
  randomSeed(analogRead(0));
  delay(10);
  lcd.init();
  lcd.backlight();
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  wifiConnect();
  
  client.setServer(mqttServer, port);
  
  dht.begin();
}


void wifiConnect() {
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    long r = random(100);
    char clientId[20];
    sprintf(clientId, "clientId-%ld", r);
    if (client.connect(clientId)) {
      Serial.print(clientId);
      Serial.println(" connected");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void loop() {
  lcd.setCursor(0,0);
  if (!client.connected()) {
    reconnect();
  }
  delay(200);
  float h = dht.readHumidity();
  float t = dht.readTemperature();

  if (isnan(h) || isnan(t)) {
  Serial.println("Failed to read from DHT sensor!");
  return;
  }
  char tempString[8];
  dtostrf(t, 1, 2, tempString);

  if(client.publish("esp32/temperature", tempString) == true){
    lcd.clear();
    lcd.print("Success:");
    lcd.setCursor(0,1);
    lcd.print(tempString);
  }else{
    lcd.clear();
    lcd.print("Fail");
  }
  delay(10); 
  client.loop();
}