#include <Adafruit_MPU6050.h>
#include <Adafruit_Sensor.h>
#include <Wire.h>
#include <DHT.h>
#include <ArduinoJson.h>
#include <PubSubClient.h>
#include <WiFi.h>

#define DHT_PIN 4 
#define DHT_TYPE DHT22

#define MQTT_SERVER "broker.emqx.io"
#define MQTT_PORT 1883
#define MQTT_TOPIC "data/mpu_dht/9821921"

const char* ssid = "Wokwi-GUEST";
const char* password = "";

DHT dht(DHT_PIN, DHT_TYPE);
Adafruit_MPU6050 mpu;

WiFiClient espClient;
PubSubClient client(espClient);

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");

    if (client.connect("ESP32Client-send982121")) {
      Serial.println("connected");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void setup(void) {
  Serial.begin(115200);
  while (!Serial)
    delay(10);

  Serial.println("Adafruit MPU6050 test!");

  if (!mpu.begin()) {
    Serial.println("Failed to find MPU6050 chip");
    while (1) {
      delay(10);
    }
  }
  Serial.println("MPU6050 Found!");

  mpu.setAccelerometerRange(MPU6050_RANGE_8_G);
  mpu.setGyroRange(MPU6050_RANGE_500_DEG);
  mpu.setFilterBandwidth(MPU6050_BAND_5_HZ);

  dht.begin();

  // Connect to WiFi
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(250);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");

  // Connect to MQTT broker
  client.setServer(MQTT_SERVER, MQTT_PORT);

  Serial.println("");
  delay(100);
}

void loop() {

  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  sensors_event_t a, g, temp;
  mpu.getEvent(&a, &g, &temp);

  float temperature = dht.readTemperature();
  float humidity = dht.readHumidity();

  // Create a JSON document
  DynamicJsonDocument doc(2048);
  JsonObject jsonData = doc.createNestedObject("data");
  jsonData["accel_x"] = a.acceleration.x;
  jsonData["accel_y"] = a.acceleration.y;
  jsonData["accel_z"] = a.acceleration.z;
  jsonData["gyro_x"] = g.gyro.x;
  jsonData["gyro_y"] = g.gyro.y;
  jsonData["gyro_z"] = g.gyro.z;
  jsonData["temperature"] = temperature;
  jsonData["humidity"] = humidity;

  // Serialize JSON to a string
  String jsonString;
  serializeJson(doc, jsonString);

  // Print the JSON string
  Serial.println(jsonString);

  client.publish(MQTT_TOPIC, jsonString.c_str());

  delay(5000);
}