#include <WiFi.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <NTPClient.h>
#include <WiFiUdp.h>

// WiFi credentials
const char* ssid = "Wokwi-GUEST";
const char* password = "";  // No password

// OLED display settings
#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels
#define OLED_RESET    -1 // Reset pin # (or -1 if sharing Arduino reset pin)
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

WiFiUDP ntpUDP;
NTPClient timeClient(ntpUDP);

void setup() {
  Serial.begin(115200);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.println("Connecting to WiFi...");
  }
  Serial.println("Connected to WiFi");

  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println(F("SSD1306 allocation failed"));
    for (;;);
  }
  display.display();
  delay(2000);
  display.clearDisplay();
  
  timeClient.begin();
  timeClient.setTimeOffset(0);
}

String formatDate(time_t rawTime) {
  struct tm * ptm = gmtime(&rawTime);
  char dateBuffer[20];
  sprintf(dateBuffer, "%02d/%02d/%04d", ptm->tm_mday, ptm->tm_mon+1, ptm->tm_year+1900);
  return String(dateBuffer);
}

void loop() {
  timeClient.update();

  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);
  display.setCursor(0, 0);

  long epochTime = timeClient.getEpochTime();
  String currentDate = formatDate(epochTime);

  display.println("Current Date:");
  display.println(currentDate);
  display.println("Current Time:");
  display.println(timeClient.getFormattedTime());
  display.display();

  delay(1000);
}