#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH 128 
#define SCREEN_HEIGHT 64 
#define OLED_RESET     2 
#define SCREEN_ADDRESS 0x3C 
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

int xc, yc, xp, yp;
char str[10];
unsigned long t1;

void setup() {
  Serial.begin(9600);
  if(!display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS)) {
    Serial.println(F("SSD1306 allocation failed"));
    for(;;); // Don't proceed, loop forever
  }

  //display.setTextSize(1);      // Normal 1:1 pixel scale
  display.setTextColor(SSD1306_WHITE); // Draw white text
  display.cp437(true);         // Use full 256 char 'Code Page 437' font
  
  display.clearDisplay();
  xc = display.width()/4;
  yc = display.height()/2;

  //drawArc(xc,yc,-235,235,30);
  
}

void drawArc(int x1, int y1, int a1, int a2, int raggio) {
  int x;
  int y;
  display.clearDisplay();

  // costruisce gauge meter
  for (int j=a1; j<=a2; j += 5) {
    float a = ((float)j)/100.0 - (PI/2.0);
    x = x1 + (int)(cos(a) * raggio);
    y = y1 + (int)(sin(a) * raggio);
    display.drawPixel(x, y, SSD1306_WHITE);
  }
  float a = ((float)a2)/100.0 - (PI/2.0);
  for (int r=0; r<=5; r++) {
    x = x1 + (int)(cos(a) * (raggio-r));
    y = y1 + (int)(sin(a) * (raggio-r));
    display.drawPixel(x, y, SSD1306_WHITE);
  }
  a = ((float)a1)/100.0 - (PI/2.0);
  for (int r=0; r<=5; r++) {
    x = x1 + (int)(cos(a) * (raggio-r));
    y = y1 + (int)(sin(a) * (raggio-r));
    display.drawPixel(x, y, SSD1306_WHITE);
  }

  // ccostruisce lancetta
  int v = analogRead(A0);
  int val = v;
  v = map(v, 0, 1023, a1, a2);
  a = ((float)v)/100.0 - (PI/2.0);
  x = x1 + (int)(cos(a) * (raggio-3));
  y = y1 + (int)(sin(a) * (raggio-3));
  display.drawLine(xc,yc, x, y, SSD1306_WHITE);

  // scrive valori
  display.setCursor(20, 55);  
  sprintf(str,"%4d ", val);
  display.setTextSize(1);
  display.drawRect(18, 53, 30, 11, SSD1306_WHITE);
  display.write(str); 
  display.setCursor(80, 2);
  int perc = map(val, 0, 1023, 0, 100);  
  sprintf(str,"%d%%", perc);
  display.setTextSize(2);
  display.write(str);


  display.display();
}

void loop() {
  if ((millis() - t1) > 100) {
    drawArc(xc,yc,-235,235,30);
    t1 = millis();
  }
}