#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <Keypad.h>

#define I2C_ADDR 0x27
#define LCD_WIDTH 12
#define LCD_HEIGHT 6
#define MAX_CODE_LENGTH 4

const byte ROWS = 4;
const byte COLS = 4;
const char* desiredCode = "123A"; 
const int greenLedPin = 13;
const int redLedPin = 12;

char keys[ROWS][COLS] = {
  {'1', '2', '3', 'A'},
  {'4', '5', '6', 'B'},
  {'7', '8', '9', 'C'},
  {'*', '0', '#', 'D'}
};
byte rowPins[ROWS] = {9, 8, 7, 6};
byte colPins[COLS] = {5, 4, 3, 2};

Keypad keypad = Keypad(makeKeymap(keys), rowPins, colPins, ROWS, COLS);
LiquidCrystal_I2C lcd(I2C_ADDR, LCD_WIDTH, LCD_HEIGHT);

char enteredCode[MAX_CODE_LENGTH + 1]; 
int codeIndex = 0;   
bool checkCode = false; 

void displayInitialMessage() {
  lcd.setCursor(0, 0);
  lcd.print("Enter PIN:");
  lcd.setCursor(0, 1);
  lcd.print("'*' to check!");
  lcd.setCursor(12, 0);
}

void setup() {
  lcd.init();
  lcd.backlight();
  displayInitialMessage();
  Serial.begin(115200); 
  Serial.println("Keys you pressed:\n");
  pinMode(greenLedPin, OUTPUT);
  pinMode(redLedPin, OUTPUT);
}

void checkEnteredCode() {
  enteredCode[codeIndex] = '\0';

  if (strcmp(enteredCode, desiredCode) == 0) {
    lcd.clear();
    lcd.print("PIN is Correct!");
    digitalWrite(greenLedPin, HIGH); 
    digitalWrite(redLedPin, LOW);    
    delay(3000); 
    digitalWrite(greenLedPin, LOW); 
  } else {
    lcd.clear();
    lcd.print("PIN is Wrong!");
    digitalWrite(greenLedPin, LOW); 
    digitalWrite(redLedPin, HIGH);   
    delay(3000); 
    digitalWrite(redLedPin, LOW);  
  }

  codeIndex = 0;
  checkCode = false;
  lcd.clear();
  displayInitialMessage();
}

void loop() {
  char key = keypad.getKey();

  if (key != NO_KEY) {
    Serial.println("Key pressed: " + String(key));
    
    if (key == '*') {
      checkCode = true;
      lcd.clear();
      lcd.print("Processing PIN");
      delay(1500);
      checkEnteredCode();
    } else {
      if (codeIndex < MAX_CODE_LENGTH) {
        enteredCode[codeIndex++] = key;
        lcd.print(key);
      }
    }
  }
}