// Include libraries
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <DHTesp.h>
#include <WiFi.h>

// Define OLED parameters
#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
#define OLED_RESET -1
#define SCREEN_ADDRESS 0x3C

#define LED_1 12
#define Buzzer 14
#define PB_ok 35
#define PB_up 32
#define PB_down 33
#define PB_cancel 25
#define dht 26

#define NTP_SERVER "pool.ntp.org"
#define UTC_OFFSET 0
#define UTC_OFFSET_DST 0

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

DHTesp dhtSensor;

int hours = 0;
int minutes = 0;
int newOFFSET = 0;

bool alarm_enabled = true;
int n_alarms = 3;
int alarm_hours[] = {0, 1, 2};
int alarm_minutes[] = {1, 10, 20};
bool alarm_triggered[] = {false, false, false};

int n_notes = 8;
int C = 262;
int D = 294;
int E = 330;
int F = 349;
int G = 392;
int A = 440;
int B = 494;
int C_H = 523;
int notes[] = {C, D, E, F, G, A, B, C_H};

int current_mode = 0;
int max_modes = 5;
String modes[] = {"1 - Set Time Zone", "2 - Set Alarm 1", "3 - Set Alarm 2", 
                  "4 - Set Alarm 3", "5 - Disable all Alarms"};

void setup() {
  Serial.begin(115200);
  pinMode(LED_1, OUTPUT);
  pinMode(Buzzer, OUTPUT);
  pinMode(PB_cancel, INPUT);
  pinMode(PB_ok, INPUT);
  pinMode(PB_up, INPUT);
  pinMode(PB_down, INPUT);

  dhtSensor.setup(dht, DHTesp :: DHT22);

  if (!display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS)) {
    Serial.println(F("SSD1306 allocation failed"));
    for (;;);
  }

  display.display();
  delay(500);

  WiFi.begin("Wokwi-GUEST", "", 6);
  display.clearDisplay();

  while (WiFi.status() != WL_CONNECTED) {
    print_line("Connecting to WIFI", 0, 0, 2);
  }

  display.clearDisplay();
  print_line("Connected to WIFI", 0, 0, 2);
  delay(500);

  configTime(UTC_OFFSET, UTC_OFFSET_DST, NTP_SERVER);

  display.clearDisplay();
  print_line("Welcome to Medibox!", 0, 15, 2);
  delay(500);

}

void loop() {

  if (digitalRead(PB_ok) == LOW) {
    delay(200);
    go_to_menu();
  }

  display.clearDisplay();
  print_time_with_check_alarm();
  check_temp();
}


void print_line(String text, int column, int row, int text_size) {
  display.setTextSize(text_size);
  display.setTextColor(SSD1306_WHITE);
  display.setCursor(column, row);
  display.println(text);
  display.display();
}


void update_print_time() {
  struct tm timeinfo;
  getLocalTime(&timeinfo);

  char time_hour[3];  
  strftime(time_hour, 3, "%H", &timeinfo);
  hours = atoi(time_hour);

  char time_minute[3];
  strftime(time_minute, 3, "%M", &timeinfo);  
  minutes = atoi(time_minute);

  char time[9];
  strftime(time, 9, "%H:%M:%S", &timeinfo);
  
  print_line(time, 15, 0, 2);
}


void ring_alarm() {
  display. clearDisplay();
  print_line("Medicine Time!", 0, 0, 2);
  digitalWrite(LED_1, HIGH);

  bool break_happened = false;
  while (break_happened == false && digitalRead(PB_cancel) == HIGH) {
    for (int i = 0; i < n_notes; i++) {
      if (digitalRead(PB_cancel) == LOW) {
        delay(200);
        break_happened = true;
        break;
      }
      tone(Buzzer, notes[i]);
      delay(500);
      noTone(Buzzer);
      delay(2);
    }
  }
  digitalWrite(LED_1, LOW);
  display.clearDisplay();
}


void print_time_with_check_alarm(void) {
  update_print_time();

  if (alarm_enabled == true) {
    for (int i = 0; i < n_alarms ; i++) {
      if (alarm_triggered[i] == false && hours == alarm_hours[i] && minutes == alarm_minutes[i]) {
        ring_alarm();
        alarm_triggered[i] = true;
      }
    }
  }
}


int button_pressed() {
  while (true) {
    if (digitalRead(PB_up) == LOW) {
      delay(200);
      return PB_up;     // returns the pin number of PB_up
    }

    else if (digitalRead(PB_down) == LOW) {
      delay(200);
      return PB_down;
    }

    else if (digitalRead(PB_ok) == LOW) {
      delay(200);
      return PB_ok;
    }

    else if (digitalRead(PB_cancel) == LOW) {
      delay(200);
      return PB_cancel;
    }
  }
}


void go_to_menu() {
  while (true) {
    display.clearDisplay();
    print_line(modes[current_mode], 0, 0, 2);

    int pressed = button_pressed();
    if (pressed == PB_up) {
      delay(200);
      current_mode += 1;
      if (current_mode > max_modes - 1) {
        current_mode = 0;
      }
    }
    else if (pressed == PB_down) {
      delay(200);
      current_mode -= 1;
      if (current_mode < 0) {
        current_mode = max_modes - 1;
      }
    }
    else if (pressed == PB_ok) {
      delay(200);
      run_mode(current_mode);
    }
    else if (pressed == PB_cancel) {
      delay(200);
      current_mode = 0;
      break;
    }
  }
}


void run_mode(int mode) {
  if (mode == 0) {
    set_time_zone();
  }
  else if (mode == 1 || mode == 2 || mode == 3) {
    set_alarm(mode - 1);
  }
  else if (mode == 4) {
    alarm_enabled = false;     // All alarms will be disabled
    display.clearDisplay();
    print_line("Alarms Disabled", 0, 0, 2);
    delay(1000);
  }
}


void set_time_zone() {

  int temp_hours = 0;
  while (true) {
    display.clearDisplay();
    print_line("Enter UTC hours: " + String(temp_hours), 0, 0, 2);

    int pressed = button_pressed();
    if (pressed == PB_up) {
      delay(200);
      temp_hours += 1;
      if (temp_hours > 14) {
        temp_hours = -12;
      }
    }
    else if (pressed == PB_down) {
      delay(200);
      temp_hours -= 1;
      if (temp_hours < -12) {
        temp_hours = 14;
      }
    }
    else if (pressed == PB_ok) {
      delay(200);
      break;
    }
    else if (pressed == PB_cancel) {
      delay(200);
      break;
    }
  }

  int temp_minutes = 0;
  while (true) {
    display.clearDisplay();
    print_line("Enter UTC minutes : " + String(temp_minutes), 0, 0, 2);

    int pressed = button_pressed();
    if (pressed == PB_up) {
      delay(200);
      temp_minutes += 1;
      if (temp_minutes > 59) {
        temp_minutes = 0;

      }
    }
    else if (pressed == PB_down) {
      delay(200);
      temp_minutes -= 1;
      if (temp_minutes < 0) {
        temp_minutes = 59;

      }
    }
    else if (pressed == PB_ok) {
      delay(200);
      break;
    }
    else if (pressed == PB_cancel) {
      delay(200);
      break;
    }
  }

  if (temp_hours >= 0) {
    newOFFSET = 3600 * temp_hours + 60 * temp_minutes;
  }
  if (temp_hours < 0) {
    newOFFSET = 3600 * temp_hours - 60 * temp_minutes;
  }

  configTime(newOFFSET, UTC_OFFSET_DST, NTP_SERVER);
  display.clearDisplay();
  print_line("Time Zone is set", 0, 0, 2);
  delay(1000);
}


void set_alarm(int alarm) {

  int temp_hours = alarm_hours[alarm];
  while (true) {
    display.clearDisplay();
    print_line("Enter the hour: " + String(temp_hours), 0, 0, 2);

    int pressed = button_pressed();
    if (pressed == PB_up) {
      delay(200);
      temp_hours += 1;
      if (temp_hours > 23) {   // or temp_hours = temp_hours % 24
        temp_hours = 0;
      }
    }
    else if (pressed == PB_down) {
      delay(200);
      temp_hours -= 1;
      if (temp_hours < 0) {
        temp_hours = 23;
      }
    }
    else if (pressed == PB_ok) {
      delay(200);
      alarm_hours[alarm] = temp_hours;
      break;
    }
    else if (pressed == PB_cancel) {
      delay(200);
      break;
    }
  }

  int temp_minutes = alarm_minutes[alarm];
  while (true) {
    display.clearDisplay();
    print_line("Enter the minute: " + String(temp_minutes), 0, 0, 2);

    int pressed = button_pressed();
    if (pressed == PB_up) {
      delay(200);
      temp_minutes += 1;
      if (temp_minutes > 59) {   // or temp_minutes = temp_minutes % 60
        temp_minutes = 0;
      }
    }
    else if (pressed == PB_down) {
      delay(200);
      temp_minutes -= 1;
      if (temp_minutes < 0) {
        temp_minutes = 59;
      }
    }
    else if (pressed == PB_ok) {
      delay(200);
      alarm_minutes[alarm] = temp_minutes;
      display.clearDisplay();
      print_line("Alarm is set", 0, 0, 2);
      delay(1000);
      break;
    }
    else if (pressed == PB_cancel) {
      delay(200);
      break;
    }
  }
}


void check_temp() {
  TempAndHumidity data = dhtSensor.getTempAndHumidity();
  if (data.temperature > 32) {
    print_line("TEMP HIGH", 0, 30, 1);
  }
  else if (data.temperature < 26) {
    print_line("TEMP LOW", 0, 30, 1);
  }

  if (data.humidity > 80) {
    print_line("HUMIDITY HIGH", 0, 50, 1);
  }
  else if (data.humidity < 60) {
    print_line("HUMIDITY LOW", 0, 50, 1);
  }
  if (digitalRead(PB_ok) == LOW) {
    delay(200);
    go_to_menu();
  }
  delay(500);
}