Wokwi - Online ESP32, STM32, Arduino Simulator

/* Contoh ESP32 HTTP IoT Server untuk Wokwi.com

   https://wokwi.com/projects/320964045035274834

   Untuk menguji, Anda memerlukan Wokwi IoT Gateway, seperti yang dijelaskan di sini:

   https://docs.wokwi.com/guides/esp32-wifi#the-private-gateway

   Kemudian mulai simulasi, dan buka http://localhost:9080
   di tab browser lain.

   Perhatikan bahwa IoT Gateway memerlukan langganan Wokwi Club.
   Untuk membeli langganan Wokwi Club, pergi ke https://wokwi.com/club
*/

#include <WiFi.h>
#include <WiFiClient.h>
#include <WebServer.h>
#include <uri/UriBraces.h>

#define WIFI_SSID "Wokwi-GUEST"
#define WIFI_PASSWORD ""
// Mendefinisikan kecepatan saluran WiFi mempercepat koneksi:
#define WIFI_CHANNEL 6

WebServer server(80);

const int LED1 = 26;
const int LED2 = 27;

bool led1State = false;
bool led2State = false;

void kirimHtml() {
  String respons = R"(
    <!DOCTYPE html><html>
      <head>
        <title>ESP32 Web Server Demo</title>
        <meta name="viewport" content="width=device-width, initial-scale=1">
        <style>
          html { font-family: sans-serif; text-align: center; }
          body { display: inline-flex; flex-direction: column; }
          h1 { margin-bottom: 1.2em; } 
          h2 { margin: 0; }
          div { display: grid; grid-template-columns: 1fr 1fr; grid-template-rows: auto auto; grid-auto-flow: column; grid-gap: 1em; }
          .btn { background-color: #5B5; border: none; color: #fff; padding: 0.5em 1em;
                 font-size: 2em; text-decoration: none }
          .btn.OFF { background-color: #333; }
        </style>
      </head>
            
      <body>
        <h1>ESP32 Web Server</h1>

        <div>
          <h2>LED 1</h2>
          <a href="/toggle/1" class="btn LED1_TEXT">LED1_TEXT</a>
          <h2>LED 2</h2>
          <a href="/toggle/2" class="btn LED2_TEXT">LED2_TEXT</a>
        </div>
      </body>
    </html>
  )";
  respons.replace("LED1_TEXT", led1State ? "ON" : "OFF");
  respons.replace("LED2_TEXT", led2State ? "ON" : "OFF");
  server.send(200, "text/html", respons);
}

void setup(void) {
  Serial.begin(115200);
  pinMode(LED1, OUTPUT);
  pinMode(LED2, OUTPUT);

  WiFi.begin(WIFI_SSID, WIFI_PASSWORD, WIFI_CHANNEL);
  Serial.print("Menghubungkan ke WiFi ");
  Serial.print(WIFI_SSID);
  // Tunggu koneksi
  while (WiFi.status() != WL_CONNECTED) {
    delay(100);
    Serial.print(".");
  }
  Serial.println(" Terhubung!");

  Serial.print("Alamat IP: ");
  Serial.println(WiFi.localIP());

  server.on("/", kirimHtml);

  server.on(UriBraces("/toggle/{}"), []() {
    String led = server.pathArg(0);
    Serial.print("Mengganti LED #");
    Serial.println(led);

    switch (led.toInt()) {
      case 1:
        led1State = !led1State;
        digitalWrite(LED1, led1State);
        break;
      case 2:
        led2State = !led2State;
        digitalWrite(LED2, led2State);
        break;
    }

    kirimHtml();
  });

  server.begin();
  Serial.println("Server HTTP dimulai");
}

void loop(void) {
  server.handleClient();
  delay(2);
}