#include <WiFi.h>
#include <ThingSpeak.h>
#include "DHTesp.h"
char ssid[] = "Wokwi-GUEST";
char pass[] = "";
WiFiClient client;
unsigned long myChannelNumber = 2464316;
const char * myWriteAPIKey = "WOKXUUA2WS50EPO4";
DHTesp dhtSensor;
TempAndHumidity data;
const int DHT_PIN = 15;
const int TRIG_PIN = 19;
const int ECHO_PIN = 17;
long duration, distance;
int statusCode;
void setup() {
  Serial.begin(115200);
  WiFi.mode(WIFI_STA);
  ThingSpeak.begin(client);
  dhtSensor.setup(DHT_PIN, DHTesp::DHT22);
  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);
}
void loop() {
  connectToCloud();
  computeData();
  writeData();
  delay(1000);
}
void connectToCloud(){
  if(WiFi.status() != WL_CONNECTED) {
    Serial.print("Attempting to connect");
    while(WiFi.status() != WL_CONNECTED) {
      WiFi.begin(ssid, pass);
      for(int i=0;i<5;i++) {
        Serial.print(".");
        delay(1000);
      }

 }
    Serial.println("\nConnected.");
  }
}
void computeData(){
  distance = getDistanceInCentimeters();
  data = dhtSensor.getTempAndHumidity();
  Serial.println("-----------");
  Serial.println("Humi: " + String(data.humidity));
  Serial.println("Temp: " + String(data.temperature));
  Serial.println("Dist: " + String(distance));
  Serial.println("-----------");
}
void writeData(){
  ThingSpeak.setField(1, data.humidity);
  ThingSpeak.setField(2, data.temperature);
  ThingSpeak.setField(3, distance);
  statusCode =  ThingSpeak.writeFields(myChannelNumber,myWriteAPIKey);
  if(statusCode == 200)  //successful writing code
    Serial.println("Channel update successful.");
  else
    Serial.println("Problem Writing data. HTTP error code :" +
String(statusCode));
  delay(15000); // data to be uploaded every 15secs
}
long  getDistanceInCentimeters() {
  digitalWrite(TRIG_PIN,LOW);
  delayMicroseconds(2);
  digitalWrite(TRIG_PIN, HIGH);
  delayMicroseconds(10);
  digitalWrite(TRIG_PIN, LOW);
  duration = pulseIn(ECHO_PIN, HIGH);
  return (duration * 0.034 / 2);
}