#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <PubSubClient.h>
#include <WiFi.h>
#include "DHTesp.h"

const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqtt_server = "broker.hivemq.com";
const int mqtt_port = 1883;
const int DHT_PIN = 15;
const int LED_PIN = 2;

WiFiClient espClient;
PubSubClient client(espClient);

LiquidCrystal_I2C lcd(0x27, 16, 2);
DHTesp dhtSensor;

unsigned long lastMsg = 0;
const long interval = 2000;

void setup() {
  Serial.begin(115200);
  lcd.init();
  lcd.backlight();
  setupWifi();
  client.setServer(mqtt_server, mqtt_port);
  client.setCallback(callback);
  dhtSensor.setup(DHT_PIN, DHTesp::DHT22);
  pinMode(LED_PIN, OUTPUT);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  unsigned long now = millis();
  if (now - lastMsg > interval) {
    lastMsg = now;
    float temperature = dhtSensor.getTemperature();
    float humidity = dhtSensor.getHumidity();

    displayLCD(temperature, humidity);
    controlLED(temperature, humidity);
    publishData(temperature, humidity);
  }
}

void setupWifi() {
  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");

  String message = "";
  for (int i = 0; i < length; i++) {
    message += (char)payload[i];
  }

  Serial.println(message);

  if (strcmp(topic, "topicName/Weather") == 0) {
    handleWeatherMessage(message);
  }
}

void handleWeatherMessage(String message) {
  if (message.equals("1")) {
    publishTemperature();
  } else if (message.equals("2")) {
    publishHumidity();
  } else if (message.equals("3")) {
    publishTemperature();
    publishHumidity();
  }
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    String clientId = "ESP32Client-";
    clientId += String(random(0xffff), HEX);

    if (client.connect(clientId.c_str())) {
      Serial.println("Connected to " + clientId);
      client.subscribe("topicName/Weather");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void displayLCD(float temperature, float humidity) {
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("Nhiet do: " + String(temperature, 2) + "°C");
  lcd.setCursor(0, 1);
  lcd.print("Do am: " + String(humidity, 1) + "%");
}

void controlLED(float temperature, float humidity) {
  if (temperature > 23 && humidity > 35) {
    digitalWrite(LED_PIN, HIGH);
  } else {
    digitalWrite(LED_PIN, LOW);
  }
}

void publishData(float temperature, float humidity) {
  char tempStr[10];
  char humStr[10];
  dtostrf(temperature, 4, 2, tempStr);
  dtostrf(humidity, 4, 2, humStr);

  client.publish("topicName/Weather/temperature", tempStr);
  client.publish("topicName/Weather/humidity", humStr);
}

void publishTemperature() {
  float temperature = dhtSensor.getTemperature();
  char tempStr[10];
  dtostrf(temperature, 4, 2, tempStr);
  client.publish("topicName/Weather/temperature", tempStr);
}

void publishHumidity() {
  float humidity = dhtSensor.getHumidity();
  char humStr[10];
  dtostrf(humidity, 4, 2, humStr);
  client.publish("topicName/Weather/humidity", humStr);
}