/* This sketch sends a character string as Morse characters by flashing light and audio
   Don't want the LED? Simply don't connect one to the board

*/

struct t_mtab { char c, pat; } ;

struct t_mtab morsetab[] = {
  {'.', 106},
	{',', 115},
	{'?', 76},
	{'/', 41},
	{'A', 6},
	{'B', 17},
	{'C', 21},
	{'D', 9},
	{'E', 2},
	{'F', 20},
	{'G', 11},
	{'H', 16},
	{'I', 4},
	{'J', 30},
	{'K', 13},
	{'L', 18},
	{'M', 7},
	{'N', 5},
	{'O', 15},
	{'P', 22},
	{'Q', 27},
	{'R', 10},
	{'S', 8},
	{'T', 3},
	{'U', 12},
	{'V', 24},
	{'W', 14},
	{'X', 25},
	{'Y', 29},
	{'Z', 19},
	{'1', 62},
	{'2', 60},
	{'3', 56},
	{'4', 48},
	{'5', 32},
	{'6', 33},
	{'7', 35},
	{'8', 39},
	{'9', 47},
	{'0', 63}
} ;

#define N_MORSE  (sizeof(morsetab)/sizeof(morsetab[0]))

#define SPEED  (15)  //code is stable up to 35 WPM
#define DOTLEN  (1200/SPEED)
#define DASHLEN  (3*(1200/SPEED))
#define LEDSPACE (150) //Space between LED on and LED off
#define CHARSPACE (100) // Space between Morse characters

int LEDpin = 4; //Needs to be PWM pin
int SPKRpin = 3; //Needs to be PWM pin

void dash()
{

  analogWrite(SPKRpin, 128) ;//128 default
  delay(LEDSPACE); //the handy timing spacer to separate LED flashes
  analogWrite(LEDpin,128) ;//128 default
  delay(DASHLEN);
  analogWrite(SPKRpin, 0) ; 
  analogWrite(LEDpin, 0) ;
  delay(LEDSPACE) ;//the handy timing spacer to separate LED flashes
}

void dit()
{

  analogWrite(SPKRpin, 128) ;//128 default
  delay(LEDSPACE);
  analogWrite(LEDpin, 128) ;//128 default
  delay(DOTLEN);
  analogWrite(SPKRpin, 0) ; 
  analogWrite(LEDpin, 0) ;
  delay(LEDSPACE);
}

void
send(char c)
{
  int i ;
  if (c == ' ') {
    Serial.print(c) ;
    delay(7*DOTLEN) ;
    return ;
  }
  for (i=0; i<N_MORSE; i++) {
    if (morsetab[i].c == c) {
      unsigned char p = morsetab[i].pat ;
      Serial.print(morsetab[i].c) ;

      while (p != 1) {
          if (p & 1)
            dash() ;
          else
            dit() ;
          p = p / 2 ;
      }
      delay(2*DOTLEN) ;
      delay(CHARSPACE*4);
      return ;
    }
  }
  /* if we drop off the end, then we send a space */
  Serial.print("?") ;
}

void
sendmsg(char *str)
{
  while (*str)
    send(*str++) ;
  Serial.println("");
}

void setup() {
  pinMode(LEDpin, OUTPUT) ;
  Serial.begin(9600) ; //serial unnecessary except debugging as needed
  Serial.println("Morse Code Test") ;
 
  //Serial.println("") ;
}

void loop() {
  Transmit();
 }

void Transmit(){//Make sure these are all CAPS or will not TX
   sendmsg("S5") ;
 //   sendmsg("ABCDEFGHIJKLMNOPQRSTUVWXYZ") ;

  delay(1000) ;
}