#include <SoftwareSerial.h>
#include <SD.h>
#include <SPI.h>
#include <TinyGPS++.h>

const int chipSelect = 5;
File root;
File selFile;
File gpsLogFile;

String gpsLogFilename;

bool gpsLogEnable = false;

#define gpsSSTX 2
#define gpsSSRX 15

SoftwareSerial gpsSS(gpsSSRX, gpsSSTX);
TinyGPSPlus gps;

bool gpsOut = true;

bool debug = false;

//Commands ------------------
String comList[] = {
  "help", //0 - help
  "ls", // 1 - rootls
  "write", // 2 - write [file name] [content]
  "mkdir", // 3 - mkdir [dir name]
  "rmdir", // 4 - rmdir [dir name]
  "rm", // 5 - remove [file name]
  "cat", //6 - fieldump
  "gps", //7 - gps
  "gpsLog", //8 - gpsLog ([file name || true/false])
  "debug" //9 - debug
};
//---------------------------
void setup() {
 // Open serial communications and wait for port to open:
  Serial.begin(115200);
  // wait for Serial Monitor to connect. Needed for native USB port boards only:
  while (!Serial);

  Serial.print("Initializing SD card...");

  if (!SD.begin(chipSelect)) {
    Serial.println("initialization failed. Things to check:");
    Serial.println("1. is a card inserted?");
    Serial.println("2. is your wiring correct?");
    Serial.println("3. did you change the chipSelect pin to match your shield or module?");
    Serial.println("Note: press reset button on the board and reopen this Serial Monitor after fixing your issue!");
    while (true);
  }

  Serial.println("initialization done.");

  root = SD.open("/");

  printDirectory(root, 0);

  Serial.println("done!");

  Serial.println("GPS_SS Initialization ...");
  gpsSS.begin(9600);
}

void loop() {
  if(Serial.available() > 0){
    String serialIn = Serial.readStringUntil('\n');
    exec(serialIn);
  }

  gpsData();
}

void printDirectory(File dir, int numTabs) {
  while (true) {

    File entry =  dir.openNextFile();
    if (! entry) {
      // no more files
      break;
    }
    for (uint8_t i = 0; i < numTabs; i++) {
      Serial.print('\t');
    }
    Serial.print(entry.name());
    if (entry.isDirectory()) {
      Serial.println("/");
      printDirectory(entry, numTabs + 1);
    } else {
      // files have sizes, directories do not
      Serial.print("\t\t");
      Serial.println(entry.size(), DEC);
    }
    entry.close();
  }
}

void exec(String command){
  String mainCommand = command.substring(0, command.indexOf(' '));
  String commandCtx1 = command.substring(command.indexOf(' ')+1, command.indexOf(' ', command.indexOf(' ')+1));
  String commandCtx2 = command.substring(command.indexOf(' ', command.indexOf(' ')+1)+1);
  
  //Debug innfo ----------------
  if(debug){
    Serial.println("Debug info:");
    Serial.println(mainCommand);
    Serial.println(commandCtx1);
    Serial.println(commandCtx2);
    Serial.println(find(mainCommand));
    Serial.println("End of Debug info");
  }

  
  //------------------------------ Command definition ------------------------------
  switch(find(mainCommand)){
    case -1:
      Serial.println("Error!! : Command not in command list (comList)");
      break;
    case 0:   //help
      Serial.println("Possible commannds are:");
      for(String comX : comList){
        Serial.println(comX);
      }
      break;
    case 1:   //rootls
      root = SD.open("/");
      Serial.println("Listing directory!:");
      printDirectory(root, 0);
      break;
    case 2:   //write
      if(commandCtx1.substring(commandCtx1.indexOf('.')) == ".txt"){
        if(SD.exists(commandCtx1)){
          Serial.println("writinng to existing file");
        }else{
          Serial.println("This file does not exist ... creatinng now one");
        }
        commandCtx1.trim();
        selFile = SD.open(commandCtx1, FILE_WRITE);
        selFile.seek(selFile.size());
        selFile.println(commandCtx2);
        selFile.close();
      }else{
        Serial.println("Error!! : Filetypes other than .txt are not allowed");
      }
      break;
    case 3:    //mkdir
      Serial.print("Creating directory : ");
      Serial.println(commandCtx1);
      if(SD.mkdir(commandCtx1)){
        Serial.print("Creation of : ");
        Serial.print(commandCtx1);
        Serial.println("   succesful!");
      }else{
        Serial.println("Directory creation failed!");
      }
      break;
    case 4:   //rmdir
      Serial.print("Removing directory : ");
      Serial.println(commandCtx1);
      if(SD.rmdir(commandCtx1)){
        Serial.print("Removal of : ");
        Serial.print(commandCtx1);
        Serial.println("   succesful!");
      }else{
        Serial.println("Directory removal failed!");
      }
      break;
    case 5:   //remove
      if(SD.exists(commandCtx1)){
        Serial.println("Deleting file...");
        Serial.print("Deletion ");
        if(SD.remove(commandCtx1)){
          Serial.println("successful");
        }else{
          Serial.println("failed!!");
        }
      }else{
        Serial.println("This file does not exist!!");
      }
      break;
    case 6:   //cat
      selFile = SD.open(commandCtx1, FILE_READ);
      if (selFile) {
        Serial.println("File opened: " + commandCtx1);
        while (selFile.available()) {
          Serial.write(selFile.read());
        }
        selFile.close();
        Serial.println();
        Serial.println("File closed");
      } else {
        Serial.println("Error!! : File not correctly opened");
      }
      break;
    case 7:   //gps
      Serial.println("Toggleing GPS Output...");
      gpsOut = !gpsOut;
      break;
    case 8:   //gpsLog
      if(mainCommand == commandCtx1){
        Serial.print("gpsLog set to: ");
        Serial.println(gpsLogEnable);
        Serial.print("gpsLogFile :");
        Serial.println(gpsLogFilename);
      }else if(commandCtx1 == "true" || commandCtx1 == "false"){
        if(commandCtx1 == "true"){
          gpsLogEnable = true;
        }else{
          gpsLogEnable = false;
        }
      }else{
        gpsLogFilename = commandCtx1;
      }
      break;
    case 9:
      Serial.print("debug now ...");
      if(debug){
        Serial.println("inactive");
      }else{
        Serial.println("active");
      }
      debug = !debug;
      break;  
    default:   //default
      Serial.println("Error!! : Command found in (comList) but nnot definned in exec switch");
      break;
  }
}

int find(String findStr){
  for(int i = 0; i < sizeof(comList); i++){
    if(findStr == comList[i]){
      return i;
    }
  }
  return -1;
}

void gpsData(){
  for (unsigned long start = millis(); millis() - start < 1000;){
    while(gpsSS.available() > 0){
      gps.encode(gpsSS.read());
    }
  }
  
  if(gps.location.isUpdated()){
    if(gpsOut){
      Serial.print("LAT= ");
      Serial.print(gps.location.lat(), 6);
      Serial.print("   LON= ");
      Serial.print(gps.location.lng(), 6);
      Serial.print("   ALT= ");
      Serial.print(gps.altitude.meters());
      Serial.print("   SPEED= ");
      Serial.print(gps.speed.kmph());

      Serial.print("   COURSEv= ");
      Serial.println(gps.course.value());
      Serial.print("   COURSEd= ");
      Serial.println(gps.course.deg());

      Serial.print("            SAT= ");
      Serial.print(gps.satellites.value());
      Serial.print("   PREC= ");
      Serial.print(gps.hdop.value());

      Serial.print("            RAWDATE= ");
      Serial.print(gps.date.value());
      Serial.print("   RAWTIME= ");
      Serial.println(gps.time.value());
    }
    //log GPS
    gpsLog(String("LAT=" + String(gps.location.lat(), 6) + " LON=" + String(gps.location.lng(), 6) + " ALT=" + String(gps.altitude.meters()) + " SPEED=" + String(gps.speed.kmph()) + " SAT=" + String(gps.satellites.value()) + " RAWDATE=" + String(gps.date.value()) + " RAWTIME=" + String(gps.time.value()) + " HDOP=" + String(gps.course.value()) + " COURSEd=" + String(gps.course.deg())));
  }else{
    if(debug){
      Serial.println("GPS: No Update!");
      Serial.print("Chars processed: ");
      Serial.println(gps.charsProcessed());
    }
    gpsLog("NU"); // NU = No Update
  }
}

void gpsLog(String input){
  if(gpsLogEnable){
    gpsLogFile = SD.open(gpsLogFilename, FILE_WRITE);
    gpsLogFile.seek(gpsLogFile.size());
    gpsLogFile.println(input);
    gpsLogFile.close();
    if(debug){
      Serial.println(String("gpsLog: " + input));
    }
  }
}