#include <WiFi.h>
#include "DHTesp.h"
#include "ThingSpeak.h"
#include <Wire.h>
#include <Adafruit_MPU6050.h>
#include <Adafruit_Sensor.h>
#include <LiquidCrystal_I2C.h>
#include <ESP32Servo.h>

// WiFi and ThingSpeak settings
const char* WIFI_NAME = "Wokwi-GUEST";
const char* WIFI_PASSWORD = "";
const int myChannelNumber = 2488258;
const char* myApiKey = "WT0JBMU8VBKWJ0L5";
const char* server = "api.thingspeak.com";

// DHT sensor settings
const int DHT_PIN = 15;

// LED pin
const int LED_PIN = 13;

// Servo motor settings
#define MOTOR_PIN   4 
Servo s;

// MPU6050 settings
Adafruit_MPU6050 mpu;

// LCD settings
#define I2C_ADDR    0x27
#define LCD_COLUMNS 16
#define LCD_LINES   2
LiquidCrystal_I2C lcd(I2C_ADDR, LCD_COLUMNS, LCD_LINES);

// Threshold temperature for servo motor activation
#define THRESHOLD_TEMP  25 

// WiFi client
WiFiClient client;

// DHT sensor instance
DHTesp dhtSensor;

void setup() {
  Serial.begin(115200);

  // Setup DHT sensor
  dhtSensor.setup(DHT_PIN, DHTesp::DHT22);

  // Setup WiFi
  WiFi.begin(WIFI_NAME, WIFI_PASSWORD);
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.println("Wifi not connected");
  }
  Serial.println("Wifi connected !");
  Serial.println("Local IP: " + String(WiFi.localIP()));

  // Setup ThingSpeak
  ThingSpeak.begin(client);

  // Setup LCD
  lcd.init();
  lcd.backlight();

  // Setup MPU6050
  if (!mpu.begin()) {
    Serial.println("MPU6050 not found");
    while (1) {
      delay(20);
    }
  }

  // Setup servo motor
  s.attach(MOTOR_PIN); 

  // Setup LED pin
  pinMode(LED_PIN, OUTPUT);

  Serial.println("Setup completed");
}

void loop() {
  // Read data from DHT sensor
  TempAndHumidity data = dhtSensor.getTempAndHumidity();

  // Send data to ThingSpeak
  ThingSpeak.setField(1, data.temperature);
  ThingSpeak.setField(2, data.humidity);
  int x = ThingSpeak.writeFields(myChannelNumber, myApiKey);
  
  // Control LED based on temperature and humidity
  if (data.temperature > 35 || data.temperature < 12 || data.humidity > 70 || data.humidity < 40) {
    digitalWrite(LED_PIN, HIGH);
  } else {
    digitalWrite(LED_PIN, LOW);
  }

  // Print temperature and humidity to Serial monitor
  Serial.println("Temp: " + String(data.temperature, 2) + "°C");
  Serial.println("Humidity: " + String(data.humidity, 1) + "%");

  // Print ThingSpeak status to Serial monitor
  if (x == 200) {
    Serial.println("Data pushed successfully");
  } else {
    Serial.println("Push error" + String(x));
  }

  // Print MPU6050 data to Serial monitor
  sensors_event_t accel, gyro, temp;
  mpu.getEvent(&accel, &gyro, &temp);
  Serial.println("Acceleration on X axis:");
  Serial.println(accel.acceleration.x);
  Serial.println("Rotation of X axis:");
  Serial.println(gyro.gyro.x * 180 / PI); // Convert radians to degrees

  // Print temperature and humidity to LCD
  lcd.setCursor(0, 0);
  lcd.print("  Temp: " + String(data.temperature, 1) + "\xDF" + "C  ");
  lcd.setCursor(0, 1);
  lcd.print(" Humidity: " + String(data.humidity, 1) + "% ");

  // Map temperature to servo position
  int servoPos = map(data.temperature, 0, 100, 0, 180);
  
  // Control servo motor based on temperature
  if (data.temperature > THRESHOLD_TEMP) {
    s.write(servoPos); 
    Serial.println("Motor started!");
  } else {
    s.write(0); 
    Serial.println("Motor stopped!");
  }

  delay(10000); // Adjust delay as needed
}