#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <DHT.h>

// Pin definitions
const int gasSensorPin = A1;
const int ldrSensorPin = A0;
const int triggerPin = 9;
const int echoPin = 8;
const int redLedPin = 12;
const int greenLedPin = 10;
const int blueLedPin = 11;
const int buzzerPin = 7;
const int DHTPin = 2;

// Threshold values
const int gasThreshold = 450;
const int ldrThreshold = 400;
const int distanceThreshold = 15;

// Sensor values
int gasValue = 0;
int ldrValue = 0;
int distance = 0;

// OLED display
#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
#define OLED_RESET -1
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

// DHT sensor
#define DHTTYPE DHT22
DHT dht(DHTPin, DHTTYPE);

void setup() {
  pinMode(gasSensorPin, INPUT);
  pinMode(ldrSensorPin, INPUT);
  pinMode(triggerPin, OUTPUT);
  pinMode(echoPin, INPUT);
  pinMode(redLedPin, OUTPUT);
  pinMode(greenLedPin, OUTPUT);
  pinMode(blueLedPin, OUTPUT);
  pinMode(buzzerPin, OUTPUT);

  Serial.begin(9600);

  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println(F("SSD1306 allocation failed"));
    for(;;);
  }

  display.clearDisplay();
  display.display();

  dht.begin();
}

void loop() {
  readGasSensor();
  readLdrSensor();
  distance = getDistance();

  float temperature = dht.readTemperature();
  float humidity = dht.readHumidity();

  triggerOutputs();

  displaySensorValues(temperature, humidity);

  delay(1000);
}

void readGasSensor() {
  gasValue = analogRead(gasSensorPin);
}

void readLdrSensor() {
  ldrValue = analogRead(ldrSensorPin);
}

void triggerOutputs() {
  digitalWrite(redLedPin, (gasValue > gasThreshold) ? HIGH : LOW);
  digitalWrite(buzzerPin, (gasValue > gasThreshold) ? HIGH : LOW);
  digitalWrite(blueLedPin, (ldrValue > ldrThreshold) ? HIGH : LOW);
  digitalWrite(greenLedPin, (distance < distanceThreshold) ? HIGH : LOW);
}

int getDistance() {
  digitalWrite(triggerPin, LOW);
  delayMicroseconds(2);
  digitalWrite(triggerPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(triggerPin, LOW);
  long duration = pulseIn(echoPin, HIGH);
  int distance = duration * 0.034 / 2;
  return distance;
}

void displaySensorValues(float temperature, float humidity) {
  display.clearDisplay();
  display.setTextSize(2);
  display.setTextColor(SSD1306_WHITE);
  display.setCursor(0, 0);
  display.print(F("Temperatu:"));
  
  display.print(temperature);
  
  display.println(F(" C"));
  display.print(F("Humidity: "));
  display.print(humidity);
  display.println(F(" %"));
  display.display();
}