#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>

const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqtt_server = "broker.emqx.io";
const int mqtt_port = 1883;
const char* mqtt_user = ""; 
const char* mqtt_password = ""; 
const char* clientID = "mqttx_ebf3f5bd";

WiFiClient espClient;
PubSubClient client(espClient);

#define LED 26  // Using GPIO 2 for the onboard LED
#define DHTPIN 15 
#define DHTTYPE DHT22 

DHT dht(DHTPIN, DHTTYPE);

const char* temperature_topic = "sensor64048808/temperature";
const char* humidity_topic = "sensor64048808/humidity";
const char* relay_topic = "sensor64048808/relay";
const char* topic = "sensor64048808";

void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived in topic: ");
  Serial.println(topic);
  Serial.print("Message: ");
  String data = "";
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
    data += (char)payload[i];
  }
  Serial.println();
  Serial.print("Message size: ");
  Serial.println(length);
  Serial.println();
  Serial.println("-----------------------");
  Serial.println(data);

  if (String(topic) == relay_topic) {
    if (data == "ON") {
      Serial.println("Turning LED ON");
      digitalWrite(LED, HIGH);
    } else if (data == "OFF") {
      Serial.println("Turning LED OFF");
      digitalWrite(LED, LOW);
    }
  }
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    if (client.connect(clientID, mqtt_user, mqtt_password)) {
      Serial.println("MQTT connected");
      client.subscribe(relay_topic);
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void setup() {
  Serial.begin(9600);
  pinMode(LED, OUTPUT);  // Set LED pin as output
  setup_wifi();
  client.setServer(mqtt_server, mqtt_port);
  client.setCallback(callback);
  if (!client.connected()) {
    reconnect();
  } 
  dht.begin();
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  float temperature = dht.readTemperature();
  float humidity = dht.readHumidity();
  Serial.print("Temperature: ");
  Serial.print(temperature);
  Serial.println(" °C");
  Serial.print("Humidity: ");
  Serial.print(humidity);
  Serial.println(" %");

  char temperatureStr[10];
  dtostrf(temperature, 5, 2, temperatureStr);
  char humidityStr[10];
  dtostrf(humidity, 5, 2, humidityStr);
  
  client.publish(temperature_topic, temperatureStr);
  delay(200);
  client.publish(humidity_topic, humidityStr);

  delay(200);
}