// ============ Include Library ===================
#include <WiFi.h>
#include <WiFiClientSecure.h>
#include <PubSubClient.h>
#include <Arduino_JSON.h>
// ============ End Include Library ===================
// ============ Define Pin ===================
#define LDR_PIN 34
// ============ End Define Pin ==============
// ============ Variabel ===================
const char ssid[] = "Wokwi-GUEST";
const char pass[] = "";
// ============ MQTT ===============
const char *mqttServer = "wcfe8ec8.ala.asia-southeast1.emqxsl.com";
const char *topic_ldr = "mentoring/sensor/cahaya";
const char *mqtt_username = "esp32";
const char *mqtt_password = "esp32";
int port = 8883;
// ============ End MQTT ===============
const float gama = 0.7;
const float rl10 = 50;
float kecerahan = 0;
unsigned long lastTime = 0;
unsigned long intervalTime = 1000;

static const char *root_ca PROGMEM = R"EOF(
-----BEGIN CERTIFICATE-----
MIIDrzCCApegAwIBAgIQCDvgVpBCRrGhdWrJWZHHSjANBgkqhkiG9w0BAQUFADBh
MQswCQYDVQQGEwJVUzEVMBMGA1UEChMMRGlnaUNlcnQgSW5jMRkwFwYDVQQLExB3
d3cuZGlnaWNlcnQuY29tMSAwHgYDVQQDExdEaWdpQ2VydCBHbG9iYWwgUm9vdCBD
QTAeFw0wNjExMTAwMDAwMDBaFw0zMTExMTAwMDAwMDBaMGExCzAJBgNVBAYTAlVT
MRUwEwYDVQQKEwxEaWdpQ2VydCBJbmMxGTAXBgNVBAsTEHd3dy5kaWdpY2VydC5j
b20xIDAeBgNVBAMTF0RpZ2lDZXJ0IEdsb2JhbCBSb290IENBMIIBIjANBgkqhkiG
9w0BAQEFAAOCAQ8AMIIBCgKCAQEA4jvhEXLeqKTTo1eqUKKPC3eQyaKl7hLOllsB
CSDMAZOnTjC3U/dDxGkAV53ijSLdhwZAAIEJzs4bg7/fzTtxRuLWZscFs3YnFo97
nh6Vfe63SKMI2tavegw5BmV/Sl0fvBf4q77uKNd0f3p4mVmFaG5cIzJLv07A6Fpt
43C/dxC//AH2hdmoRBBYMql1GNXRor5H4idq9Joz+EkIYIvUX7Q6hL+hqkpMfT7P
T19sdl6gSzeRntwi5m3OFBqOasv+zbMUZBfHWymeMr/y7vrTC0LUq7dBMtoM1O/4
gdW7jVg/tRvoSSiicNoxBN33shbyTApOB6jtSj1etX+jkMOvJwIDAQABo2MwYTAO
BgNVHQ8BAf8EBAMCAYYwDwYDVR0TAQH/BAUwAwEB/zAdBgNVHQ4EFgQUA95QNVbR
TLtm8KPiGxvDl7I90VUwHwYDVR0jBBgwFoAUA95QNVbRTLtm8KPiGxvDl7I90VUw
DQYJKoZIhvcNAQEFBQADggEBAMucN6pIExIK+t1EnE9SsPTfrgT1eXkIoyQY/Esr
hMAtudXH/vTBH1jLuG2cenTnmCmrEbXjcKChzUyImZOMkXDiqw8cvpOp/2PV5Adg
06O/nVsJ8dWO41P0jmP6P6fbtGbfYmbW0W5BjfIttep3Sp+dWOIrWcBAI+0tKIJF
PnlUkiaY4IBIqDfv8NZ5YBberOgOzW6sRBc4L0na4UU+Krk2U886UAb3LujEV0ls
YSEY1QSteDwsOoBrp+uvFRTp2InBuThs4pFsiv9kuXclVzDAGySj4dzp30d8tbQk
CAUw7C29C79Fv1C5qfPrmAESrciIxpg0X40KPMbp1ZWVbd4=
-----END CERTIFICATE-----
)EOF";

// ============ End Variabel ===================
// ============ Class ===================
WiFiClientSecure espClient;
PubSubClient client(espClient);
// ============ End Class ===================
// ============ Function ===================
void wifi_init();
void mqtt_init();
void ldr_read();
void send_data();
// ============ End Function ===================
void setup() {
  Serial.begin(115200);
  wifi_init();
  mqtt_init();
}

void loop() {
  client.loop();
  if (!client.connected()) {
    mqtt_init();
  }
  send_data();
}
void wifi_init() {
  Serial.print("Connecting to WiFi");
  WiFi.begin(ssid, pass, 6);
  while (WiFi.status() != WL_CONNECTED) {
    delay(100);
    Serial.print(".");
  }
  Serial.println(" Connected!");
}
void mqtt_init() {
  espClient.setCACert(root_ca);
  client.setServer(mqttServer, port);
  while (!client.connected()) {
    String client_id = "mentoring-iot-6-";
    client_id += String(WiFi.macAddress());
    Serial.printf("The client %s connects to the public MQTT broker\n", client_id.c_str());
    if (client.connect(client_id.c_str(), mqtt_username, mqtt_password)) {
      Serial.println("Public EMQX MQTT broker connected");
    } else {
      Serial.print("failed with state ");
      Serial.print(client.state());
      delay(2000);
    }
  }
}
void ldr_read() {
  int nilaiLDR = analogRead(LDR_PIN);
  nilaiLDR = map(nilaiLDR, 4095, 0, 1024, 0);
  float voltase = nilaiLDR / 1024.*5;
  float resistansi = 2000 * voltase / (1-voltase/5);
  kecerahan = pow(rl10*1e3*pow(10,gama)/resistansi,(1/gama));
  Serial.print("Kecerahan = ");
  Serial.println(kecerahan);
}
void send_data() {
  if ((millis() - lastTime) > intervalTime) {
    if (!client.connected()) {
      mqtt_init();
    }
    ldr_read();
    JSONVar dataObject;
    dataObject["nilai"] = kecerahan;

    String sData = JSON.stringify(dataObject);

    client.publish(topic_ldr, sData.c_str());

    lastTime = millis();
  }
}