#include <WiFi.h>
#include <PubSubClient.h>
#include <ESP32Servo.h>

const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqtt_server = "broker.emqx.io";
const char* mqtt_username = "emqx";
const char* mqtt_password = "test";
const int mqtt_port = 1883;

int ledPin = 22;

Servo servo; // Inisialisasi objek Servo

WiFiClient espClient;
PubSubClient client(espClient);

void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("WiFi connected - IP address: ");
  Serial.println(WiFi.localIP());
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    if (client.connect("ESP32Client", mqtt_username, mqtt_password)) {
      Serial.println("connected");
      client.subscribe("monitoring/sensor/suhu");
      client.subscribe("monitoring/sensor/kelembapan");
      client.subscribe("monitoring/sensor/cahaya");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void setup() {
  Serial.begin(115200);
  setup_wifi();
  client.setServer(mqtt_server, mqtt_port);
  client.setCallback(callback); // Menetapkan fungsi callback
  servo.attach(21); // Menghubungkan servo ke pin 21
  servo.write(0); // Set servo ke posisi awal (0 derajat)
  pinMode(ledPin, OUTPUT);
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  
  String message;
  for (int i = 0; i < length; i++) {
    message += (char)payload[i];
  }
  
  Serial.println(message);

  // Check topic and perform action accordingly
  if (strcmp(topic, "monitoring/sensor/suhu") == 0) {
    float temperature = message.toFloat();
    if (temperature > 25) {
      servo.write(90); // Activate servo if temperature is above 25°C
    } else {
      servo.write(0); // Deactivate servo if temperature is below or equal to 25°C
    }
  } else if (strcmp(topic, "monitoring/sensor/kelembapan") == 0) {
    float humidity = message.toFloat();
    if (humidity < 60) {
      servo.write(90); // Activate servo if humidity is below 60%
    } else {
      servo.write(0); // Deactivate servo if humidity is 60% or above
    }
  } else if (strcmp(topic, "monitoring/sensor/cahaya") == 0) {
    float lightLevel = message.toFloat();
    if (lightLevel > 800) {
      digitalWrite(ledPin, HIGH); // Turn on LED or perform any other action for light level above 800
    } else {
      digitalWrite(ledPin, LOW);// Turn off LED or perform any other action for light level 800 or below
    }
  }
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();
}