#include <WiFi.h>
#include <WiFiClientSecure.h>
#include <PubSubClient.h>
#include <Arduino_JSON.h>
#include <ESP32Servo.h>

#define SERVO_PIN 18 // Menggunakan pin 18 untuk servo
#define LED_PIN 4
const char ssid[] = "Wokwi-GUEST";
const char pass[] = "";

const char *mqttServer = "ce5fa058.ala.asia-southeast1.emqxsl.com";
const char *topic_servo = "monitoring/aktuator/servo";
const char *topic_cahaya = "monitoring/sensor/cahaya";
const char *topic_aktuator  = "monitoring/aktuator/led";
const char *mqtt_username = "srireskita";
const char *mqtt_password = "Reskita2509";
int port = 8883;

unsigned long lastTime = 0;
unsigned long intervalTime = 1000;

static const char *root_ca PROGMEM = R"EOF(
-----BEGIN CERTIFICATE-----
MIIDrzCCApegAwIBAgIQCDvgVpBCRrGhdWrJWZHHSjANBgkqhkiG9w0BAQUFADBh
MQswCQYDVQQGEwJVUzEVMBMGA1UEChMMRGlnaUNlcnQgSW5jMRkwFwYDVQQLExB3
d3cuZGlnaWNlcnQuY29tMSAwHgYDVQQDExdEaWdpQ2VydCBHbG9iYWwgUm9vdCBD
QTAeFw0wNjExMTAwMDAwMDBaFw0zMTExMTAwMDAwMDBaMGExCzAJBgNVBAYTAlVT
MRUwEwYDVQQKEwxEaWdpQ2VydCBJbmMxGTAXBgNVBAsTEHd3dy5kaWdpY2VydC5j
b20xIDAeBgNVBAMTF0RpZ2lDZXJ0IEdsb2JhbCBSb290IENBMIIBIjANBgkqhkiG
9w0BAQEFAAOCAQ8AMIIBCgKCAQEA4jvhEXLeqKTTo1eqUKKPC3eQyaKl7hLOllsB
CSDMAZOnTjC3U/dDxGkAV53ijSLdhwZAAIEJzs4bg7/fzTtxRuLWZscFs3YnFo97
nh6Vfe63SKMI2tavegw5BmV/Sl0fvBf4q77uKNd0f3p4mVmFaG5cIzJLv07A6Fpt
43C/dxC//AH2hdmoRBBYMql1GNXRor5H4idq9Joz+EkIYIvUX7Q6hL+hqkpMfT7P
T19sdl6gSzeRntwi5m3OFBqOasv+zbMUZBfHWymeMr/y7vrTC0LUq7dBMtoM1O/4
gdW7jVg/tRvoSSiicNoxBN33shbyTApOB6jtSj1etX+jkMOvJwIDAQABo2MwYTAO
BgNVHQ8BAf8EBAMCAYYwDwYDVR0TAQH/BAUwAwEB/zAdBgNVHQ4EFgQUA95QNVbR
TLtm8KPiGxvDl7I90VUwHwYDVR0jBBgwFoAUA95QNVbRTLtm8KPiGxvDl7I90VUw
DQYJKoZIhvcNAQEFBQADggEBAMucN6pIExIK+t1EnE9SsPTfrgT1eXkIoyQY/Esr
hMAtudXH/vTBH1jLuG2cenTnmCmrEbXjcKChzUyImZOMkXDiqw8cvpOp/2PV5Adg
06O/nVsJ8dWO41P0jmP6P6fbtGbfYmbW0W5BjfIttep3Sp+dWOIrWcBAI+0tKIJF
PnlUkiaY4IBIqDfv8NZ5YBberOgOzW6sRBc4L0na4UU+Krk2U886UAb3LujEV0ls
YSEY1QSteDwsOoBrp+uvFRTp2InBuThs4pFsiv9kuXclVzDAGySj4dzp30d8tbQk
CAUw7C29C79Fv1C5qfPrmAESrciIxpg0X40KPMbp1ZWVbd4=
-----END CERTIFICATE-----
)EOF";

WiFiClientSecure espClient;
PubSubClient client(espClient);
Servo servo; // Inisialisasi objek servo

void setup() {
  Serial.begin(115200);
  wifi_init();
  mqtt_init();
  servo.attach(SERVO_PIN);
  pinMode(LED_PIN, OUTPUT);
}

void loop() {
  client.loop();
  if (!client.connected()) {
    mqtt_init();
  }
  // control_servo();
}

void wifi_init() {
  Serial.print("Connecting to WiFi");
  WiFi.begin(ssid, pass, 6);
  while (WiFi.status() != WL_CONNECTED) {
    delay(100);
    Serial.print(".");
  }
  Serial.println(" Connected!");
}

void mqtt_init() {
  espClient.setCACert(root_ca);
  client.setServer(mqttServer, port);
  client.setCallback(callback);
  while (!client.connected()) {
    String client_id = "servo-led-controller-1";
    client_id += String(WiFi.macAddress());
    Serial.printf("The client %s connects to the public MQTT broker\n", client_id.c_str());
    if (client.connect(client_id.c_str(), mqtt_username, mqtt_password)) {
      Serial.println("Public EMQX MQTT broker connected");
      client.subscribe(topic_servo);
      client.subscribe(topic_cahaya);
      client.subscribe(topic_aktuator);
    } else {
      Serial.print("failed with state ");
      Serial.print(client.state());
      delay(2000);
    }
  }
}

void callback(char *topic, byte *payload, unsigned int length) {

    String sMsg;
    Serial.print("Message arrived in topic: ");
    Serial.println(topic);
    Serial.print("Message:");
    for (int i = 0; i < length; i++) {
      Serial.print((char) payload[i]);
      sMsg += (char) payload[i];
    }
    JSONVar objMsg = JSON.parse(sMsg);
    process_data(objMsg);

    Serial.println();
    Serial.println("-----------------------");
}

void process_data(JSONVar jsonObject) {
  if (JSON.typeof(jsonObject) == "undefined") {
    Serial.println("Gagal mendapatkan data karena type undefined");
    return;
  }
  Serial.println("jsonObject :");
  Serial.println(jsonObject);

  // Handling light sensor (LDR) data to control the LED
  if (jsonObject.hasOwnProperty("LDR")) {
    int ldr = jsonObject["LDR"]; // Assuming LDR value is sent as an integer

    if (ldr > 800) {
      digitalWrite(LED_PIN, HIGH);
      Serial.println("LED turned on due to high light level");
    } else {
      digitalWrite(LED_PIN, LOW);
      Serial.println("LED turned off due to low light level");
    }
  }

  // Handling LED control data
  if (jsonObject.hasOwnProperty("LED")) {
    int ledState = jsonObject["LED"]; // Assuming LED state is sent as an integer (1 for ON, 0 for OFF)

    if (ledState == 1) {
      digitalWrite(LED_PIN, HIGH); // Turn on LED
      Serial.println("LED turned on");
    } else {
      digitalWrite(LED_PIN, LOW); // Turn off LED
      Serial.println("LED turned off");
    }
  }

  // Example of handling other data, e.g., temperature and humidity
  if (jsonObject.hasOwnProperty("temperature") && jsonObject.hasOwnProperty("humidity")) {
    int temperature = jsonObject["temperature"];
    int humidity = jsonObject["humidity"];
  
    if (temperature > 25 && humidity < 60) {
      // Aktifkan servo
      servo.write(90); // Sudut 90 derajat
      Serial.println("Servo turned on");
    } else {
      // Nonaktifkan servo
      servo.write(0); // Sudut 0 derajat
      Serial.println("Servo turned off");
    }
  }
}





//Bayu Sutra
//IoT-1