#include <WiFi.h> // Thêm thư viện WiFi
#include <PubSubClient.h> // Thêm thư viện PubSubClient để kết nối đến MQTT broker
#include <DHTesp.h> // Thêm thư viện DHTesp để đọc dữ liệu từ cảm biến DHT22

const int DHT_PIN = 15; // Định nghĩa chân kết nối với cảm biến DHT22
DHTesp dht; // Khởi tạo đối tượng DHTesp

const char* ssid = "Wokwi-GUEST"; // Tên mạng WiFi
const char* password = ""; // Mật khẩu mạng WiFi
const char* mqtt_server = "mqtt-dashboard.com"; // Địa chỉ của MQTT broker
WiFiClient espClient; // Tạo đối tượng WiFiClient để kết nối WiFi
PubSubClient client(espClient); // Tạo đối tượng PubSubClient để kết nối đến MQTT broker
unsigned long lastMsg = 0; // Biến lưu trữ thời điểm gửi tin nhắn cuối cùng
float temp = 0; // Biến lưu trữ nhiệt độ
float hum = 0; // Biến lưu trữ độ ẩm

void setup_wifi() {
  delay(10); // Delay để đợi khởi động
  Serial.println();
  Serial.print("Kết nối đến ");
  Serial.println(ssid);

  WiFi.mode(WIFI_STA); // Thiết lập chế độ kết nối WiFi cho ESP32
  WiFi.begin(ssid, password); // Kết nối WiFi với tên mạng và mật khẩu đã được định nghĩa

  while (WiFi.status() != WL_CONNECTED) { // Đợi kết nối thành công
    delay(500);
    Serial.print(".");
  }

  randomSeed(micros()); // Khởi tạo seed ngẫu nhiên

  Serial.println("");
  Serial.println("Kết nối với WiFi");
  Serial.println("Địa chỉ IP: ");
  Serial.println(WiFi.localIP()); // In ra địa chỉ IP của ESP32
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.println("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }
  Serial.println();

  if ((char)payload[0] == '1') { // Nếu payload là '1'
    digitalWrite(2, LOW); // Bật đèn LED
  } else { // Nếu payload không phải '1'
    digitalWrite(2, HIGH); // Tắt đèn LED
  }
}

void reconnect() { 
  while (!client.connected()) { // Nếu chưa kết nối đến MQTT broker
    Serial.println("Đang kết nối đến MQTT...");
    String clientId = "clientId-";
    clientId += String(random(0xffff), HEX);
    if (client.connect(clientId.c_str())) { // Thử kết nối đến MQTT broker
      Serial.println("");
      Serial.println("Đã kết nối " + clientId);
      client.publish("loinguyen/dht", "Không thể kết nối "); // Gửi thông điệp đến chủ đề "loinguyen/dht"
      client.subscribe("loinguyen/dht"); // Đăng ký nhận thông điệp từ chủ đề "loinguyen/dht"
    } else {
      Serial.print("Thất bại, rc=");
      Serial.print(client.state());
      Serial.println(" Thử lại sau 5 giây");
      delay(5000);
    }
  }
}

void setup() {
  pinMode(2, OUTPUT); // Thiết lập chân 2 là đầu ra để điều khiển đèn LED
  Serial.begin(115200); // Khởi động giao tiếp Serial với baud rate 115200
  setup_wifi(); // Thiết lập kết nối WiFi
  client.setServer(mqtt_server, 1883); // Thiết lập kết nối đến MQTT broker
  client.setCallback(callback); // Thiết lập hàm callback để xử lý thông điệp nhận được từ MQTT broker
  dht.setup(DHT_PIN, DHTesp::DHT22); // Khởi động cảm biến DHT22
}

void loop() {
  if (!client.connected()) { // Nếu không kết nối đến MQTT broker
    reconnect(); // Thực hiện kết nối lại
  }
  client.loop();

  unsigned long now = millis();
  if (now - lastMsg > 2000) { // Nếu đã quá 2 giây từ lần gửi tin nhắn trước đó
    lastMsg = now; // Lưu lại thời điểm gửi tin nhắn hiện tại
    TempAndHumidity data = dht.getTempAndHumidity(); // Đọc dữ liệu nhiệt độ và độ ẩm từ cảm biến DHT22

    String temp = String(data.temperature, 2); // Lấy giá trị nhiệt độ với 2 chữ số sau dấu phẩy
    client.publish("loinguyen/dht/temp", temp.c_str()); // Gửi dữ liệu nhiệt độ đến chủ đề "loinguyen/dht/temp"
    
    String hum = String(data.humidity, 1); // Lấy giá trị độ ẩm với 1 chữ số sau dấu phẩy
    client.publish("loinguyen/dht/hum", hum.c_str()); // Gửi dữ liệu độ ẩm đến chủ đề "loinguyen/dht/hum"

    Serial.print("Nhiệt độ: "); // In ra thông điệp nhiệt độ
    Serial.println(temp); // In ra giá trị nhiệt độ
    Serial.print("Độ ẩm: "); // In ra thông điệp độ ẩm
    Serial.println(hum); // In ra giá trị độ ẩm
  }
}