#include <Arduino.h>

const int NUM_KNOBS = 5;
const int analogInputs[NUM_KNOBS] = {A0, A1, A2, A3, A4};

int analogKnobValues[NUM_KNOBS];

void updateKnobValues();
void sendKnobValues();
void printKnobValues();

void setup() { 
  for (int i = 0; i < NUM_KNOBS; i++) {
    pinMode(analogInputs[i], INPUT);
  }

  Serial.begin(9600);
}

void loop() {
  updateKnobValues();
  sendKnobValues(); // Actually send data (all the time)
  // printKnobValues(); // For debug
  delay(10);
}

void updateKnobValues() {
  for (int i = 0; i < NUM_KNOBS; i++) {
     analogKnobValues[i] = analogRead(analogInputs[i]);
  }
}

void sendKnobValues() {
  String builtString = String("");

  for (int i = 0; i < NUM_KNOBS; i++) {
    builtString += String((int)analogKnobValues[i]);

    if (i < NUM_KNOBS - 1) {
      builtString += String("|");
    }
  }
  
  Serial.println(builtString);
}

void printKnobValues() {
  for (int i = 0; i < NUM_KNOBS; i++) {
    String printedString = String("Knob #") + String(i + 1) + String(": ") + String(analogKnobValues[i]) + String(" mV");
    Serial.write(printedString.c_str());

    if (i < NUM_KNOBS - 1) {
      Serial.write(" | ");
    } else {
      Serial.write("\n");
    }
  }
}