/* 
    Author: D.O.T
    Date: 28/03/2024
    Course: EmTech 2023-2024
*/

// Wokwi heeft nog geen WiFi arduino's geintegreed dus deze code zal hier niet werken. Plak dit in een Arduino IDE

#include <SPI.h>
#include <WiFiNINA.h>

void setup() {
  Serial.begin(115200);
  if (WiFi.status() == WL_NO_MODULE) {
    Serial.println("Communication with WiFi module failed!");
    // Don't continue
    while (true);
  }

  // Check firmware version
  String fv = WiFi.firmwareVersion();
  if (fv < WIFI_FIRMWARE_LATEST_VERSION) {
    Serial.println("Please upgrade the firmware");
  }

  Serial.println("Ready to initialize WiFi ...");
}

void loop() {
  Serial.println("Scanning for WiFi networks");

  int networkCount = WiFi.scanNetworks();
  Serial.println("Scan completed");

  if (networkCount == 0) {
    Serial.println("No networks found.");
  } else {
    Serial.print(networkCount);
    Serial.println(" networks found");
    
    Serial.println("Nr | SSID                             | RSSI | CH | Encryption");
    for (int i = 0; i < networkCount; i++) {
      // Displaying network details
      Serial.print(i + 1);
      Serial.print(" | ");
      Serial.print(WiFi.SSID(i));
      Serial.print(" | ");
      Serial.print(WiFi.RSSI(i));
      Serial.print(" | ");
      Serial.print(WiFi.channel(i));
      Serial.print(" | ");

      switch (WiFi.encryptionType(i)) {
        case ENC_TYPE_NONE:
          Serial.println("Open");
          break;
        case ENC_TYPE_WEP:
          Serial.println("WEP");
          break;
        case ENC_TYPE_TKIP: // Often used with WPA
          Serial.println("WPA/TKIP");
          break;
        case ENC_TYPE_CCMP: // Often used with WPA2
          Serial.println("WPA2/CCMP");
          break;
        case ENC_TYPE_AUTO:
          Serial.println("WPA/WPA2");
          break;
        default:
          Serial.println("Unknown");
          break;
      }
    }
  }
  Serial.println("");

  delay(5000);  // wait 5 seconds before next scan
}