#include <WiFi.h>
#include <PubSubClient.h>
#include <ESP32Servo.h>

const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqtt_server = "nbad151b.ala.asia-southeast1.emqxsl.com";
const char* mqtt_username = "esp32";
const char* mqtt_password = "esp32";
const int mqtt_port = 8883;

int ledPin = 4;
Servo servo; // Inisialisasi objek Servo

WiFiClient espClient;
PubSubClient client(espClient);

void reconnect();
void callback(char* topic, byte* payload, unsigned int length);

void setup() {
  Serial.begin(115200);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(100);
    Serial.print(".");
  }
  Serial.println("WiFi connected");

  client.setServer(mqtt_server, mqtt_port);
  client.setCallback(callback);

  while (!client.connected()) {
    reconnect();
  }

  pinMode(ledPin, OUTPUT);
  servo.attach(18); // Menghubungkan servo ke pin 18
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");

  String message;
  for (int i = 0; i < length; i++) {
    message += (char)payload[i];
  }
  Serial.print("Payload: ");
  Serial.println(message);

  // Check topic and perform action accordingly
  if (strcmp(topic, "monitoring/sensor/suhu") == 0) {
    float temperature = message.toFloat();
    Serial.print("Temperature: ");
    Serial.println(temperature);
    if (temperature > 25) {
      servo.write(90); // Menggerakkan servo ke posisi tengah jika suhu di atas 25°C
    } else {
      servo.write(0); // Menggerakkan servo ke posisi awal jika suhu di bawah atau sama dengan 25°C
    }
  } else if (strcmp(topic, "monitoring/sensor/kelembapan") == 0) {
    float humidity = message.toFloat();
    Serial.print("Humidity: ");
    Serial.println(humidity);
    if (humidity < 60) {
      servo.write(90); // Menggerakkan servo ke posisi tengah jika kelembapan di bawah 60%
    } else {
      servo.write(0); // Menggerakkan servo ke posisi awal jika kelembapan 60% atau di atasnya
    }
  } else if (strcmp(topic, "monitoring/sensor/cahaya") == 0) {
    float lightLevel = message.toFloat();
    Serial.print("Light Level: ");
    Serial.println(lightLevel);
    if (lightLevel > 800) {
      digitalWrite(ledPin, HIGH); // Menghidupkan lampu jika kecerahan/cahaya melebihi batas 800
    } else {
      digitalWrite(ledPin, LOW); // Mematikan lampu jika kecerahan/cahaya 800 atau di bawahnya
    }
  }
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    if (client.connect("ESP32Client", mqtt_username, mqtt_password)) {
      Serial.println("connected");
      client.subscribe("monitoring/sensor/suhu");
      client.subscribe("monitoring/sensor/kelembapan");
      client.subscribe("monitoring/sensor/cahaya");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}