#include <WiFi.h>
#include "PubSubClient.h"

const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqttServer = "broker.emqx.io";
int port = 1883;
char clientId[50];

int ledPins[2] = {2, 13};
int ledPin = ledPins[0];

WiFiClient espClient;
PubSubClient client(espClient);

void wifiConnect() {
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
}

void mqttReconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    long r = random(1000);
    sprintf(clientId, "clientId-%ld", r);
    if (client.connect(clientId)) {
      Serial.print(clientId);
      Serial.println(" connected");
      client.subscribe("flutter/led/toggle");
      client.subscribe("flutter/led/change");

    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void callback(char* topic, byte* message, unsigned int length) {
  Serial.print("Message arrived on topic: ");
  Serial.print(topic);
  Serial.print(". Message: ");
  String stMessage;

  for (int i = 0; i < length; i++) {
    Serial.print((char)message[i]);
    stMessage += (char)message[i];
  }
  Serial.println();

  if (String(topic) == "flutter/led/toggle") {
    Serial.print("Changing output to ");
    if (stMessage == "on") {
      Serial.println("on");
      digitalWrite(ledPin, HIGH);
    }
    else if (stMessage == "off") {
      Serial.println("off");
      digitalWrite(ledPin, LOW);
    }
  }

  if (String(topic) == "flutter/led/change") {
    Serial.print("Changing led to ");
    if (stMessage == "green") {
      digitalWrite(ledPin, LOW);
      Serial.println("green");
      ledPin = ledPins[1];
      digitalWrite(ledPin, LOW);
    }
    else if (stMessage == "red") {
      digitalWrite(ledPin, LOW);
      Serial.println("red");
      ledPin = ledPins[0];
      digitalWrite(ledPin, LOW);
    }
  }


}

void setup() {
  // put your setup code here, to run once:

  Serial.begin(115200);
  Serial.println("Hello, ESP32!");

  Serial.print("Connecting to ");
  Serial.println(ssid);

  wifiConnect();

  Serial.println("");
  Serial.println("WiFi connected");

  client.setServer(mqttServer, port);
  client.setCallback(callback);

  for (int i = 0; i < 2; i++)
    pinMode(ledPins[i], OUTPUT);

}

void loop() {
  if (!client.connected()) {
    mqttReconnect();
  }
  // put your main code here, to run repeatedly:
  delay(10); // this speeds up the simulation
  client.loop();
}