#include <WiFi.h>
#include <MQTT.h>
#include <ESP32Servo.h>
#include <NusabotSimpleTimer.h>
#include <DHTesp.h>

WiFiClient net;
MQTTClient client;
NusabotSimpleTimer timer;
Servo servo;
DHTesp dhtSensor;

const char ssid[] = "Wokwi-GUEST";
const char pass[] = "";

// Variabel Pin GPIO
const int pinMerah = 27;
const int pinHijau = 26;
const int pinBiru = 25;
const int pinLED = 33;
const int pinServo = 18;
const int pinPot = 35;
const int DHT_PIN = 32;

int pot, oldPot = 0;

void setup() {
  pinMode(pinMerah, OUTPUT);
  pinMode(pinHijau, OUTPUT);
  pinMode(pinBiru, OUTPUT);
  pinMode(pinLED, OUTPUT);
  servo.attach(pinServo, 500, 2400);
  dhtSensor.setup(DHT_PIN, DHTesp::DHT22);
  
  WiFi.begin(ssid, pass);
  client.begin("adimy.cloud.shiftr.io", net);

  client.onMessage(subscribe);    // Mengekseskusi fungction "subscribe" setiap kali ada data yang diterima
  timer.setInterval(1000, publishPot);
  timer.setInterval(2000, publishDHT);

  connect();
}

void loop() {
  client.loop();
  timer.run();

  // Fitur reconnect
  if(!client.connected()){
    connect();
  }

  delay(10); // this speeds up the simulation
}

void connect(){
  rgb(1,0,0); // Merah
  while(WiFi.status() != WL_CONNECTED){
    delay(500);
  }
  rgb(0,1,0); // Hijau

  while(!client.connect("wokwi-device", "adimy", "rahasia")){
    delay(500);
  }
  rgb(0,0,1); // Biru

  client.subscribe("nusabot/#", 1);
}

void publishPot(){
  pot = analogRead(pinPot);

  // Publish jika hanya terjadi perubahan nilai potentiometer
  if(pot != oldPot){
    client.publish("nusabot/12345678/potentiometer", String(pot), false, 1);
    oldPot = pot;
  }
}

void publishDHT(){
  TempAndHumidity  data = dhtSensor.getTempAndHumidity();

  client.publish("nusabot/12345678/suhu", String(data.temperature, 2), true, 1);
  client.publish("nusabot/12345678/kelembaban", String(data.humidity, 1), true, 1);
}

void subscribe(String &topic, String &data){
  if(topic == "nusabot/12345678/led"){
    if(data == "nyala"){
      digitalWrite(pinLED, 1);
    } else {
      digitalWrite(pinLED, 0);
    }
  }

  if(topic == "nusabot/12345678/servo"){
    int pos = data.toInt();
    servo.write(pos);
  }
}

void rgb(bool red, bool green, bool blue){
  digitalWrite(pinMerah, red);
  digitalWrite(pinHijau, green);
  digitalWrite(pinBiru, blue);
}