#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>

#define DHTPIN 4            // Pin tempat Anda menghubungkan sensor DHT22
#define DHTTYPE DHT22       // Tipe sensor DHT (DHT11 atau DHT22)
#define TRIGGER_PIN 12      // Pin trigger sensor ultrasonik
#define ECHO_PIN 13         // Pin echo sensor ultrasonik
#define BUZZER_PIN 14       // Pin tempat Anda menghubungkan buzzer

DHT dht(DHTPIN, DHTTYPE);
WiFiClient espClient;
PubSubClient client(espClient);

const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqttServer = "mqtt.thingsboard.cloud"; // Alamat server MQTT ThingsBoard
const char* token = "lR7cycaLNdjvZAFFKnLo";              // Token akses perangkat di ThingsBoard

void setup() {
  Serial.begin(115200);
  delay(1000);

  pinMode(TRIGGER_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);
  pinMode(BUZZER_PIN, OUTPUT);

  dht.begin();

  connectWiFi();
  client.setServer(mqttServer, 1883);
}

void loop() {
  float temperature = dht.readTemperature(); // Baca suhu dari sensor DHT22
  float humidity = dht.readHumidity();       // Baca kelembaban dari sensor DHT22
  float waterLevel = readWaterLevel();       // Baca ketinggian air dari sensor ultrasonik

  if (!isnan(temperature) && !isnan(humidity) && !isnan(waterLevel)) {
    sendToThingsBoard(temperature, humidity, waterLevel);
    Serial.print("Suhu: ");
    Serial.print(temperature);
    Serial.print(" °C, Kelembaban: ");
    Serial.print(humidity);
    Serial.print("%, Ketinggian Air: ");
    Serial.print(waterLevel);
    Serial.println(" cm");

    // Jika ketinggian air rendah, aktifkan alarm buzzer
    if (waterLevel < 20) {
      digitalWrite(BUZZER_PIN, HIGH); // Hidupkan buzzer
      tone(BUZZER_PIN, 500);
    } else {
      digitalWrite(BUZZER_PIN, LOW); // Matikan buzzer
      noTone(BUZZER_PIN);
    }
  }

  delay(2000);
}

void connectWiFi() {
  Serial.println("Connecting to WiFi...");
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.println("Attempting to connect to WiFi..");
  }

  Serial.println("Connected to WiFi");
}

void sendToThingsBoard(float temperature, float humidity, float waterLevel) {
  if (!client.connected()) {
    reconnect();
  }

  String temperatureString = String(temperature);
  String humidityString = String(humidity);
  String waterLevelString = String(waterLevel);

  String payload = "{\"temperature\":";
  payload += temperatureString;
  payload += ",\"humidity\":";
  payload += humidityString;
  payload += ",\"water_level\":";
  payload += waterLevelString;
  payload += "}";

  client.publish("v1/devices/me/telemetry", payload.c_str());
}

void reconnect() {
  while (!client.connected()) {
    Serial.println("Connecting to ThingsBoard MQTT...");
    
    if (client.connect("ESP32Client", token, NULL)) {
      Serial.println("Connected to ThingsBoard MQTT");
    } else {
      Serial.print("Failed, rc=");
      Serial.print(client.state());
      Serial.println(" Retry in 5 seconds");
      
      delay(5000);
    }
  }
}

float readWaterLevel() {
  // Kirim sinyal ultrasonik
  digitalWrite(TRIGGER_PIN, LOW);
  delayMicroseconds(2);
  digitalWrite(TRIGGER_PIN, HIGH);
  delayMicroseconds(10);
  digitalWrite(TRIGGER_PIN, LOW);

  // Baca waktu echo kembali
  float duration = pulseIn(ECHO_PIN, HIGH);

  // Hitung ketinggian air berdasarkan waktu echo
  // (asumsi kecepatan suara adalah 343 meter per detik)
  float waterLevel = (duration / 2) * 0.0343;

  return waterLevel;
}