/*
  Arduino入門 第9回 スケッチ仕上げ
    残り時間LED制御用に関数を定義
    if文処理をswitch文に変更
*/

#include "pitch.h" // 音程周波数定義ファイル

#define TIMER 10      // タイマー時間（秒）
#define HALF_TIMER 5 // 「残り時間が半分」の時間（秒）
#define SOON_TIMER 3  // 「もうすぐ」の時間（秒）

#define SW_PIN A5 // スイッチ接続端子
#define SW_OFF 1  // スイッチOFFのdigitalReadの値

#define LED_PIN 12 // 1秒ごとに点滅するLEDの接続端子
#define LED_ON_INTERVAL   50 // LEDを点灯する時間
#define LED_OFF_INTERVAL 950 // LEDを消灯する時間

#define FULL_PIN 8 // 「残り時間十分」LEDの接続端子
#define HALF_PIN 6 // 「残り時間半分」LEDの接続端子
#define SOON_PIN 4 // 「もうすぐ」LEDの接続端子

#define SPEAKER_PIN A0  // スピーカー接続端子
#define ALARM_TONE 1760 // アラーム音の周波数

// setNokoriLed関数定義
//   positionで指定した位置の残り時間LEDのみをONにする
void setNokoriLed(int position) {
  // 最初に全部のLEDをOFFにしておく
  digitalWrite(FULL_PIN, LOW);
  digitalWrite(HALF_PIN, LOW);
  digitalWrite(SOON_PIN, LOW);

  // positionの値に応じて対応するLEDをONにする
  switch(position) {
    case 1: digitalWrite(FULL_PIN, HIGH); break;
    case 2: digitalWrite(HALF_PIN, HIGH); break;
    case 3: digitalWrite(SOON_PIN, HIGH); break;
  }
}


void setup() {  
  // LED接続端子を出力制御にする
  pinMode(LED_PIN,  OUTPUT);
  pinMode(FULL_PIN, OUTPUT);
  pinMode(HALF_PIN, OUTPUT);
  pinMode(SOON_PIN, OUTPUT);

  // スイッチ接続端子をプルアップ機能有効にする
  pinMode(SW_PIN, INPUT_PULLUP);
}

void loop() {
  // スイッチが押されるまで待つ
  while( digitalRead(SW_PIN) == SW_OFF ) {
  }

  // 「残り時間十分」LED(1番目)をON
  setNokoriLed(1);

  // 指定した時間、LEDを点滅する
  // 処理中は残り時間に応じてLEDの点灯状態を変える
  for(int i=0; i<TIMER; i++) {
    // 残り時間を計算
    int nokori = TIMER - i;

    // 残り時間が半分の時のLED(2番目)をON
    if(nokori == HALF_TIMER){
      setNokoriLed(2);
    }

    // もうすぐの時のLED(3番目)をON
    if(nokori == SOON_TIMER) {
      setNokoriLed(3);
    }

    // LEDをピカッと1秒間で点滅
    digitalWrite(LED_PIN, HIGH);
    delay(LED_ON_INTERVAL);
    digitalWrite(LED_PIN, LOW);
    delay(LED_OFF_INTERVAL);
  }

  // メロディーを鳴らす
  
  // メロディーの配列
  int melody[]={DO_4, RE_4, MI_4, RE_4, DO_4};

  // メロディー再生
  for(int i=0; i<5; i++) {
    tone(SPEAKER_PIN, melody[i]);
    delay(500);
  }

  // 音を止める
  noTone(SPEAKER_PIN);

  // LEDを消灯
  digitalWrite(SOON_PIN, LOW);
}