/* SIJA 2024 - Praktikum
  Judul Aplikasi    : ESP32 MQTT Publisher
  Deskripsi         : mengirimkan data angka over internet 
                      menggunakan protokol MQTT
  Author            : Sugiarto
--------------------------------------------------------- */

#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>

const char* ssid = "Wokwi-GUEST";
const char* password = "";

const char* mqttServer = "broker.hivemq.com";
const int mqttPort = 1883;
const char* mqttTopicTemp = "sekar/iot/suhu";
const char* mqttTopicHum = "sekar/iot/kelembaban";

const int DHTPin = 4; 
const int DHTType = DHT22; 

WiFiClient wifiClient;
PubSubClient mqttClient(wifiClient);
DHT dht(DHTPin, DHTType);

void connectToInternet() {
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
  }
  Serial.println("Connected to WiFi");
}

void setupMQTT() {
  mqttClient.setServer(mqttServer, mqttPort);
}

void reconnectMQTT() {
  Serial.println("Connecting to MQTT Broker...");
  while (!mqttClient.connected()) {
      Serial.println("Reconnecting to MQTT Broker..");

      String clientId = "ESP32Client-";
      clientId += String(random(0xffff), HEX);
      
      if (mqttClient.connect(clientId.c_str())) {
        Serial.println("Connected.");
      }      
  }
}

void setup() {
  Serial.begin(9600);
  connectToInternet();
  setupMQTT();
  dht.begin();
}

void loop() {
  if (!mqttClient.connected()) {
    reconnectMQTT();
  }

  float temperature = dht.readTemperature();
  float humidity = dht.readHumidity();

  if (!isnan(temperature) && !isnan(humidity)) {
    Serial.print("Temperature: ");
    Serial.println(temperature);
    mqttClient.publish(mqttTopicTemp, String(temperature).c_str());

    Serial.print("Humidity: ");
    Serial.println(humidity);
    mqttClient.publish(mqttTopicHum, String(humidity).c_str());
  }

  delay(5000);
}