// programa conexión a DHT11 y visualizacion info en OLED 

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <Adafruit_Sensor.h>
#include <DHT.h>

#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels

// Declaration for an SSD1306 display connected to I2C (SDA, SCL pins)
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1);

#define DHTPIN 18     // Digital pin connected to the DHT sensor

#define DHTTYPE    DHT22     // DHT 11 o DHT22

DHT dht(DHTPIN, DHTTYPE);

void setup() {
  pinMode(LED_BUILTIN, OUTPUT);  // LED_BUILTIN IS GPIO 2 
  
  Serial.begin(115200);
  
  dht.begin();

  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println(F("SSD1306 allocation failed"));
    for(;;);
  }
  delay(2000);
  display.clearDisplay();
  display.setTextColor(WHITE);
}

void loop() {
  delay(5000);
  
  static int val_led = LOW;
  val_led = val_led?LOW:HIGH;
  digitalWrite(LED_BUILTIN, val_led);   // turn on-off the LED 
  
  //read temperature and humidity
  float temp = dht.readTemperature();
  float humedad = dht.readHumidity();

  if (isnan(humedad) || isnan(temp)) {  // comprueba que se obtienen valores numéricos
    Serial.println("Failed to read from DHT sensor!");
  }

  // envia por el puerto serie la informacion
  Serial.printf(" Temperatura: %2.2f ºC    - Humedad: %2.2f %% \n", temp,  humedad );  // the double %% prints the % character
  
  // visualiza en el display la informacion
  // clear display
  display.clearDisplay();
  
  // display temperature
  display.setTextSize(1);  display.setCursor(0,0);   display.print("Temperatura: ");
  display.setTextSize(2);  display.setCursor(0,10);  display.print(temp);  display.print(" ");  
  display.setTextSize(1);  display.cp437(true);   display.write(167); // is the "º" character - https://www.ascii-code.com/CP437
  display.setTextSize(2);  display.print("C");
  
  // display humidity
  display.setTextSize(1);  display.setCursor(0, 35);  display.print("Humedad: ");  
  display.setTextSize(2);  display.setCursor(0, 45);  display.print(humedad);  display.print(" %"); 
  
  display.display(); 
}