#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>
#include <Wire.h>
#include <RTClib.h>
#include <ArduinoJson.h>

const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqtt_server = "test.mosquitto.org";
const int mqtt_port = 1883;
const char* mqtt_topic = "mqtt/FauzanAzhimaTasa/data";
const char* nama = "FauzanAzhimaTasa";

const int DHTPIN = 16;
const int DHTTYPE = DHT22;

DHT dht(DHTPIN, DHTTYPE);

WiFiClient espClient;
PubSubClient client(espClient);

RTC_DS1307 rtc;

void setup_wifi() {

  delay(10);
  // We start by connecting to a WiFi network
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }  

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void reconnect() {
  // Loop until we're reconnected
  while (!client.connected()) {
    if (client.connect("ESP32-S3Client")) {
      Serial.println("Connected");
    } 
    else {
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void setup() {
  dht.begin();
  Wire.begin(8, 9);
  rtc.begin();
  Serial.begin(115200);
  setup_wifi();
  client.setServer(mqtt_server, mqtt_port);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  float hum = dht.readHumidity();
  float temp = dht.readTemperature();

  DateTime now = rtc.now();
  String timestamp = now.timestamp(DateTime::TIMESTAMP_FULL);
  timestamp.replace("T", " ");

  DynamicJsonDocument doc(256);
  doc["nama"] = nama;
  JsonObject data = doc.createNestedObject("data");
  data["temperature"] = temp;
  data["humidity"] = hum;
  doc["timestamp"] = timestamp;

  String jsonString;
  serializeJson(doc, jsonString);

  bool publishResult = client.publish(mqtt_topic, jsonString.c_str());
  Serial.println("Datetime: " + timestamp);
  Serial.print("Temperature: " + String(temp));
  Serial.println(" *C");
  Serial.print("Humidity: " + String(hum));
  Serial.println(" %");
  Serial.println("Data Pack: " + jsonString);
  Serial.print("Result Publish: ");
  if (publishResult) {
    Serial.println("Status Publish MQTT");
  } else {
    Serial.println("Failed");
  }
  delay(5000);
}