#include <WiFi.h>
#include <PubSubClient.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>

// Cài đặt mạng WiFi
const char* ssid = "Wokwi-GUEST";
const char* password = "";

// Cài đặt MQTT broker
const char* mqtt_server = "broker.hivemq.com";
const int mqtt_port = 1883;

// Cài đặt thông tin màn hình LCD
const int LCD_COLS = 16; // Số cột của màn hình LCD
const int LCD_ROWS = 2;  // Số hàng của màn hình LCD
LiquidCrystal_I2C lcd(0x27, LCD_COLS, LCD_ROWS);  // Địa chỉ I2C của màn hình LCD


WiFiClient espClient;
PubSubClient client(espClient);

void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message received [");
  Serial.print(topic);
  Serial.print("] ");

  // Parse dữ liệu nhận được từ MQTT
  String message;
  for (int i = 0; i < length; i++) {
    message += (char)payload[i];
  }
  Serial.println(message);

  // Hiển thị dữ liệu lên màn hình LCD
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print(topic);
  lcd.setCursor(0, 1);
  lcd.print(message);
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    String clientId = "ESP32Client-";
    clientId += String(random(0xffff), HEX);

    if (client.connect(clientId.c_str())) {
      Serial.println("Connected to HiveMQ");
      client.subscribe("/dht/temperature"); // Đăng ký nhận dữ liệu nhiệt độ
      client.subscribe("/dht/humidity");    // Đăng ký nhận dữ liệu độ ẩm
    } else {
      Serial.print("Failed, rc=");
      Serial.print(client.state());
      Serial.println(" Trying again in 5 seconds");
      delay(5000);
    }
  }
}

void setup() {
  Serial.begin(115200);
  lcd.begin(LCD_COLS, LCD_ROWS);
  setup_wifi();
  client.setServer(mqtt_server, mqtt_port);
  client.setCallback(callback);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();
}