#include <Adafruit_Sensor.h>
#include <DHT_U.h>
#include <WiFi.h>
#include <PubSubClient.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define DHTPIN 12

#define DHTTYPE DHT22
DHT_Unified dht(DHTPIN, DHTTYPE);
uint32_t delayMS;

const char* ssid = "Wokwi-GUEST";
const char* password = "";

const char* mqttServer = "mqtt-dashboard.com";
const char* clientID = "clientId-YZ3ZiGHY6W"; // Client ID username+0001
const char* topic = "kelembaban";

unsigned long previousMillis = 0;
const long interval = 2000;
float temp, hum;

String msgStr = "";

#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64

#define OLED_RESET     -1
#define SCREEN_ADDRESS 0x3C
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

// Setting up WiFi and MQTT client
WiFiClient espClient;
PubSubClient client(espClient);

void setup_wifi() {
  delay(10);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void reconnect() {
  while (!client.connected()) {
    if (client.connect(clientID)) {
      Serial.println("MQTT connected");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

// Вывод данных о температуре и влажности на дисплей
void printDataToDisplay() {

  String tempStr;
  if (!isnan(temp)) {
    tempStr += temp;
  } else {
    tempStr += "-";
  }

  String humStr;
  if (!isnan(hum)) {
    humStr += hum;
  } else {
    humStr += "-";
  }

  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);

  display.setCursor(2,2);
  display.print(F("DH22 Data"));

  display.setCursor(2, 20);
  display.print(F("temperature: "));
  display.println(tempStr + "C");

  display.setCursor(2, 30);
  display.print(F("humidity: "));
  display.println(humStr + "%");

  display.display();
}

void setup() {
  Serial.begin(115200);

  dht.begin();
  sensor_t sensor;
  dht.temperature().getSensor(&sensor);
  dht.humidity().getSensor(&sensor);

  setup_wifi();
  client.setServer(mqttServer, 1883);

  if(!display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS)) {
    Serial.println(F("SSD1306 allocation failed"));
    for(;;);
  }

  display.display();
  delay(2000);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }

  client.loop();

  unsigned long currentMillis = millis();

  if (currentMillis - previousMillis >= interval) {
    previousMillis = currentMillis;
    sensors_event_t event;
    dht.temperature().getEvent(&event);

    if (isnan(event.temperature)) {
      Serial.println(F("Error reading temperature!"));
    } else {
      temp = event.temperature;
    }

    dht.humidity().getEvent(&event);

    if (isnan(event.relative_humidity)) {
      Serial.println(F("Error reading humidity!"));
    } else {
      hum = event.relative_humidity;
    }

    printDataToDisplay();

    msgStr = String(temp) + "," + String(hum) + ",";
    byte arrSize = msgStr.length() + 1;
    char msg[arrSize];
    Serial.print("PUBLISH DATA: ");
    Serial.println(msgStr);
    msgStr.toCharArray(msg, arrSize);

    client.publish(topic, msg);

    msgStr = "";
    delay(1);
  }
}