#include <WiFi.h>
#include <HTTPClient.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
#define OLED_RESET -1
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* twilioAccountSID = "AC45861e47f5425c870800499afee0909a";
const char* twilioAuthToken = "4960437948914aaf2194a5af4daddf75";
const String twilioPhoneNumber = "+17204667148";
const String destinationPhoneNumber = "+917010470155";
const int trigPin = 13; // Connect to the trig pin of the ultrasonic sensor
const int echoPin = 12; // Connect to the echo pin of the ultrasonic sensor
const int buzzerPin = 4; // Connect to the positive leg of the buzzer
const int thresholdDistance = 20; // Adjust threshold according to your garbage can size

void setup() {
  Serial.begin(115200);
  WiFi.begin(ssid, password);
  Serial.println("Connecting to WiFi...");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("WiFi connected");
  pinMode(trigPin, OUTPUT);
  pinMode(echoPin, INPUT);
  pinMode(buzzerPin, OUTPUT);
  
  if(!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) { 
    Serial.println(F("SSD1306 allocation failed"));
    for(;;);
  }
  display.display();
  delay(2000);
  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);
  display.setCursor(0,0);
  display.print("Garbage Alert:");
  display.display();
}

void loop() {
  long duration, distance;
  digitalWrite(trigPin, LOW);
  delayMicroseconds(2);
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin, LOW);
  duration = pulseIn(echoPin, HIGH);
  distance = (duration / 2) / 29.1; // Convert duration to distance in cm
  Serial.print("Distance: ");
  Serial.println(distance);
  
  if (distance < thresholdDistance) {
    display.clearDisplay();
    display.setTextSize(2);
    display.setTextColor(SSD1306_WHITE);
    display.setCursor(0,20);
    display.println("Garbage Full!");
    display.display();
    
    digitalWrite(buzzerPin, HIGH); // Turn on buzzer
    sendNotification();
    // Delay to avoid continuous notifications until distance changes
    delay(5000); // Wait for 5 seconds before sending another notification
    digitalWrite(buzzerPin, LOW); // Turn off buzzer
    display.clearDisplay();
    display.display();
  }
  delay(1000); // Wait for 1 second before next reading
}

void sendNotification() {
  Serial.println("Sending notification...");
  HTTPClient http;
  http.begin("https://api.twilio.com/2010-04-01/Accounts/" + String(twilioAccountSID) + "/Messages.json");
  http.setAuthorization(twilioAccountSID, twilioAuthToken);
  http.addHeader("Content-Type", "application/x-www-form-urlencoded");
  String postData = "To=" + destinationPhoneNumber + "&From=" + twilioPhoneNumber + "&Body=Garbage can is full!";
  int httpResponseCode = http.POST(postData);
  if (httpResponseCode > 0) {
    String response = http.getString();
    Serial.println(httpResponseCode);
    Serial.println(response);
  } else {
    Serial.print("Error on sending POST: ");
    Serial.println(httpResponseCode);
  }
  http.end();
}