#include <WiFi.h>
#include <PubSubClient.h>

#define ledg 2
#define ledy 4
#define ledr 5

const char* ssid = "Wokwi-GUEST";
const char* password = "";

const char* mqtt_server = "broker.hivemq.com";
const int mqtt_port = 1883;
const char* topicMQTT = "kinasih/komunikasi";

WiFiClient espClient;
PubSubClient clientMQTT(espClient);

void connectToInternet();
void setupMQTT();
void reconnectMQTT();

void setup() {
  pinMode(ledg, OUTPUT);
  pinMode(ledy, OUTPUT);
  pinMode(ledr, OUTPUT);
  
  Serial.begin(9600);
  connectToInternet();
  setupMQTT();
  clientMQTT.setCallback(callback);
}

void connectToInternet() {
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");
  Serial.print("IP Address: ");
  Serial.println(WiFi.localIP());
}

void setupMQTT() {
  clientMQTT.setServer(mqtt_server, mqtt_port);
}

void reconnectMQTT() {
  while (!clientMQTT.connected()) {
    Serial.print("Attempting MQTT connection...");
    String clientId = "ESP32Client-";
    clientId += String(random(0xffff), HEX);
    if (clientMQTT.connect(clientId.c_str())) {
      Serial.println("connected");
      clientMQTT.subscribe(topicMQTT);
    } else {
      Serial.print("failed, rc=");
      Serial.print(clientMQTT.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void callback(char* topic, byte* message, unsigned int length) {
  Serial.print("Message arrived on topic: ");
  Serial.print(topic);
  String messageTemp;
  for (int i = 0; i < length; i++) {
    messageTemp += (char)message[i];
  }
  Serial.println("Message: " + messageTemp);
  
  if (String(topic) == topicMQTT) {
    float temperature = parseTemperature(messageTemp);
    controlLEDs(temperature);
  }
}

float parseTemperature(String message) {
  int startIndex = message.indexOf("Temperature: ") + 13;
  int endIndex = message.indexOf("C");
  String tempString = message.substring(startIndex, endIndex);
  return tempString.toFloat();
}

void controlLEDs(float temperature) {
  if (temperature < 20) {
    digitalWrite(ledy, HIGH);
    digitalWrite(ledr, LOW);
    digitalWrite(ledg, LOW);
    Serial.println("Warning: Temperature below 20°C");
  } else if (temperature > 23) {
    digitalWrite(ledy, LOW);
    digitalWrite(ledr, HIGH);
    digitalWrite(ledg, LOW);
    Serial.println("Danger: Temperature above 23°C");
  } else {
    digitalWrite(ledy, LOW);
    digitalWrite(ledr, LOW);
    digitalWrite(ledg, HIGH);
    Serial.println("Normal: Temperature between 20°C and 23°C");
  }
}

void loop() {
  if (!clientMQTT.connected()) {
    reconnectMQTT();
  }
  clientMQTT.loop();
}