#include <WiFi.h>
#include <PubSubClient.h>
#include <DHTesp.h>

#define DHT_PIN 18

const char* ssid = "Wokwi-GUEST";
const char* password = "";

const char* mqttServer = "broker.hivemq.com";
int mqttPort = 1883;
const char* topicMQTT = "sija/iot/mqtt/smart";

WiFiClient espClient;
PubSubClient clientMQTT(espClient);
DHTesp dhtSensor;

void connectToInternet();
void setupMQTT();
void reconnectMQTT();

void setup() {
  Serial.begin(115200);
  dhtSensor.setup(DHT_PIN, DHTesp::DHT22);

  connectToInternet();
  setupMQTT();
}

void loop() {
  if (!clientMQTT.connected()) {
    reconnectMQTT();
  }
  clientMQTT.loop();

  TempAndHumidity data = dhtSensor.getTempAndHumidity();
  float temp = data.temperature;
  float hum = data.humidity;

  String payload = "Temperature: " + String(temp, 2) + " Humidity: " + String(hum, 2);
  clientMQTT.publish(topicMQTT, payload.c_str());

  Serial.println(payload);

  delay(5000); // Send data every 5 seconds
}

void connectToInternet() {
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("Connected to Wi-Fi");
  Serial.print("IP Address: ");
  Serial.println(WiFi.localIP());
}

void setupMQTT() {
  clientMQTT.setServer(mqttServer, mqttPort);
}

void reconnectMQTT() {
  while (!clientMQTT.connected()) {
    Serial.print("Attempting MQTT connection...");
    String clientId = "ESP32DHTClient-";
    clientId += String(random(0xffff), HEX);

    if (clientMQTT.connect(clientId.c_str())) {
      Serial.println("connected");
    } else {
      Serial.print("failed, rc=");
      Serial.print(clientMQTT.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}