#include <Arduino.h>

#if defined(ESP8266)
#include <ESP8266WiFi.h>
#define THINGSBOARD_ENABLE_PROGMEM 0
#elif defined(ESP32)
#include <WiFi.h>
#include "Update.h"
#endif

#define pinSensor 36
#define pinLed 2

uint32_t sensorValue;
uint32_t waterLevelValue = 69;

#include <Arduino_MQTT_Client.h>
#include <ThingsBoard.h>
//#include <secret.h>
constexpr char WIFI_SSID[] = "Wokwi-GUEST";
constexpr char WIFI_PASSWORD[] = "";
constexpr char TOKEN[] = "iHHCrYd8jruOfbpz6diE";

// Thingsboard we want to establish a connection too
constexpr char THINGSBOARD_SERVER[] = "thingsboard.ucll.cloud";
constexpr uint32_t THINGSBOARD_PORT = 31364U;

// Maximum size packets will ever be sent or received by the underlying MQTT client,
// if the size is to small messages might not be sent or received messages will be discarded
constexpr uint32_t MAX_MESSAGE_SIZE = 1024U;

// Baud rate for the debugging serial connection.
// If the Serial output is mangled, ensure to change the monitor speed accordingly to this variable
constexpr uint32_t SERIAL_DEBUG_BAUD = 115200U;

// Initialize underlying client, used to establish a connection
WiFiClient wifiClient;
// Initalize the Mqtt client instance
Arduino_MQTT_Client mqttClient(wifiClient);
// Initialize ThingsBoard instance with the maximum needed buffer size
ThingsBoard tb(mqttClient, MAX_MESSAGE_SIZE);

// For telemetry
constexpr int16_t telemetrySendInterval = 2000U;
uint32_t previousDataSend;

/// @brief Initalizes WiFi connection,
// will endlessly delay until a connection has been successfully established
void InitWiFi() {
    Serial.println("Connecting to AP ...");
    // Attempting to establish a connection to the given WiFi network
    WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
    while (WiFi.status() != WL_CONNECTED) {
        // Delay 500ms until a connection has been succesfully established
        delay(500);
        Serial.print(".");
    }
    Serial.println("Connected to AP");
}

/// @brief Reconnects the WiFi uses InitWiFi if the connection has been removed
/// @return Returns true as soon as a connection has been established again
const bool reconnect() {
    // Check to ensure we aren't connected yet
    const wl_status_t status = WiFi.status();
    if (status == WL_CONNECTED) {
        return true;
    }

    // If we aren't establish a new connection to the given WiFi network
    InitWiFi();
    return true;
}

void setup() {
    // Initalize serial connection for debugging
    Serial.begin(SERIAL_DEBUG_BAUD);
    Serial.println();
    pinMode(pinSensor, INPUT);
    delay(1000);
    InitWiFi();
}

void loop() {
    delay(100);

    if (!reconnect()) {
        return;
    }

    if (!tb.connected()) {
        // Connect to the ThingsBoard
        Serial.print("Connecting to: ");
        Serial.print(THINGSBOARD_SERVER);
        Serial.print(" with token ");
        Serial.println(TOKEN);
        if (!tb.connect(THINGSBOARD_SERVER, TOKEN, THINGSBOARD_PORT)) {
            Serial.println("Failed to connect");
            return;
        }
        // Sending a MAC address as an attribute
        tb.sendAttributeData("macAddress", WiFi.macAddress().c_str());
    }

    sensorValue = analogRead(pinSensor);
    Serial.println(sensorValue);
    sensorValue = map(sensorValue, 0, 4095, 100, 0);

    // Sending telemetry every telemetrySendInterval time
    if (millis() - previousDataSend > telemetrySendInterval) {
        previousDataSend = millis();
        tb.sendTelemetryData("temperature", random(15, 20));
        tb.sendTelemetryData("humidity", sensorValue);
        tb.sendTelemetryData("waterLevel", waterLevelValue);
        tb.sendAttributeData("rssi", WiFi.RSSI());
        tb.sendAttributeData("channel", WiFi.channel());
        tb.sendAttributeData("bssid", WiFi.BSSIDstr().c_str());
        tb.sendAttributeData("localIp", WiFi.localIP().toString().c_str());
        tb.sendAttributeData("ssid", WiFi.SSID().c_str());
    }

    tb.loop();
}