#include <WiFi.h>
#include "DHTesp.h"
#include "ThingSpeak.h"
#include <LiquidCrystal_I2C.h>

const int DHT_PIN = 15;
const int LED_PIN = 13;
const char* WIFI_NAME = "Wokwi-GUEST";
const char* WIFI_PASSWORD = "";
const int myChannelNumber = 2552512;
const char* myApiKey = "45KXBS56JMSD7AHW";
const char* server = "api.thingspeak.com";

DHTesp dhtSensor;
WiFiClient client;

// Définir les paramètres pour l'écran LCD I2C 20x4
const int LCD_ADDRESS = 0x27; // Adresse I2C de l'écran LCD
const int LCD_COLS = 20;      // Nombre de colonnes de l'écran LCD (20 pour un écran 20x4)
const int LCD_ROWS = 4;       // Nombre de lignes de l'écran LCD (4 pour un écran 20x4)
LiquidCrystal_I2C lcd(LCD_ADDRESS, LCD_COLS, LCD_ROWS);

void setup() {
  Serial.begin(115200);
  dhtSensor.setup(DHT_PIN, DHTesp::DHT22);
  pinMode(LED_PIN, OUTPUT);
  WiFi.begin(WIFI_NAME, WIFI_PASSWORD);
  while (WiFi.status() != WL_CONNECTED){
    delay(1000);
    Serial.println("Wifi not connected");
  }
  Serial.println("Wifi connected !");
  Serial.println("Local IP: " + String(WiFi.localIP()));
  WiFi.mode(WIFI_STA);
  ThingSpeak.begin(client);

  // Initialiser l'écran LCD
  lcd.init();
  lcd.backlight();
  lcd.clear();
}

void loop() {
  TempAndHumidity  data = dhtSensor.getTempAndHumidity();
  ThingSpeak.setField(1, data.temperature);
  ThingSpeak.setField(2, data.humidity);
  
  // Afficher la température et l'humidité sur l'écran LCD
  lcd.setCursor(0, 0);
  lcd.print("Temperature: ");
  lcd.print(data.temperature);
  lcd.print(" C");
  lcd.setCursor(0, 1);
  lcd.print("Humidity: ");
  lcd.print(data.humidity);
  lcd.print(" %");

  if (data.temperature > 35 || data.temperature < 12 || data.humidity > 70 || data.humidity < 40) {
    digitalWrite(LED_PIN, HIGH);
  } else {
    digitalWrite(LED_PIN, LOW);
  }
  
  int x = ThingSpeak.writeFields(myChannelNumber, myApiKey);
  
  Serial.println("Temperature: " + String(data.temperature, 2) + "°C");
  Serial.println("Humidity: " + String(data.humidity, 1) + "%");
  
  if(x == 200){
    Serial.println("Data pushed successfully");
  } else {
    Serial.println("Push error" + String(x));
  }
  Serial.println("---");

  delay(10000);
}