#include <WiFi.h>
#include <MQTT.h>
#include <ESP32Servo.h>
#include <NusabotSimpleTimer.h>
#include "DHTesp.h"

WiFiClient net;      //objek
MQTTClient client;
Servo servo;
NusabotSimpleTimer timer;
DHTesp dhtSensor;

const char ssid[] = "Wokwi-GUEST";
const char pass[] = "";

//definisi pin
const int pinRed = 2;
const int pinGreen = 4;
const int pinBlue = 16;
const int pinLED = 13;
const int pinServo = 18;
const int pinPot = 33;
const int pinDHT = 25;

int pot, oldPot = 0; //pot=data sekarang,oldpot=data sebelumnya

String serial_number = "12345678";

void setup() {
  pinMode(pinRed, OUTPUT);
  pinMode(pinGreen, OUTPUT);
  pinMode(pinBlue, OUTPUT);
  pinMode(pinLED, OUTPUT);
  servo.attach(pinServo, 540, 2400);
  pinMode(pinPot, INPUT);
  dhtSensor.setup(pinDHT, DHTesp::DHT22);
 

  Serial.begin(9600);
  WiFi.begin(ssid, pass);
  client.begin("hudan.cloud.shiftr.io", net);

  client.onMessage(subscribe);
  timer.setInterval(1000, publishPot); //untuk mengatur waktu pengiriman
  timer.setInterval(2000, publishDHT);
  connect();
}

void loop() {
  client.loop();
  timer.run();
  if (!client.connected()){
    connect();
  }
  delay(10); // this speeds up the simulation
}

void subscribe(String &topic, String &data){
  if(topic == "kelasIOT/"+ serial_number +"/led"){
    if(data == "nyala"){
      digitalWrite(pinLED, 1);
    } else if(data == "mati"){
      digitalWrite(pinLED, 0);
    }
  }

  if(topic == "kelasIOT/"+ serial_number +"/servo"){
    int posServo = data.toInt();
    servo.write(posServo);
    Serial.println(posServo); //untuk cek data masuk belum
  }
}

void publishPot(){
  pot = analogRead(pinPot);
  if(pot != oldPot){
    client.publish("kelasIOT/"+ serial_number +"/potensiometer", String(pot), true, 2);  //untuk kirim data
    oldPot = pot;
  }
  
  
}

void publishDHT(){
  TempAndHumidity  data = dhtSensor.getTempAndHumidity();
 

  client.publish("kelasIOT/"+ serial_number +"/suhu", String(data.temperature, 2), true, 2);
  client.publish("kelasIOT/"+ serial_number +"/kelembaban", String(data.humidity, 1), true, 2);
}


void rgb(bool red, bool green, bool blue) {
  digitalWrite(pinRed, red);
  digitalWrite(pinGreen, green);
  digitalWrite(pinBlue, blue);
}

void connect() {
rgb(1,0,0); //merah=terhubung ke wifi
  while(WiFi.status() != WL_CONNECTED) {
    delay(500);
  }
  rgb(0,1,0); //hijau

  client.setWill("kelasIOT/serialnumber/status", "offline", true, 2);
  while(!client.connect("clientid-unik", "hudan", "NcNB8yCCGvSyMHRg")) {
    delay(500);
  }
  rgb(0,0,1); //biru=terhubung ke broker
  client.publish("kelasIOT/serialnumber/status", "online", true, 2);
  client.subscribe("kelasIOT/#", 2); //Subcribe QOS 2
}