#include <WiFi.h>
#include <PubSubClient.h>

// Ganti dengan SSID dan Password WiFi Anda
const char* ssid = "Wokwi-GUEST";
const char* password = "";

// Alamat broker MQTT HiveMQ
const char* mqtt_server = "broker.hivemq.com";

// Inisialisasi objek WiFi dan PubSubClient
WiFiClient espClient;
PubSubClient client(espClient);

// Pin LED
const int ledPins[5] = {2, 4, 5, 18, 19};

// Fungsi callback yang akan dipanggil saat pesan diterima
void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Pesan diterima di topik: ");
  Serial.print(topic);
  Serial.print(". Pesan: ");
  String message;

  for (int i = 0; i < length; i++) {
    message += (char)payload[i];
  }
  Serial.println(message);

  // Kontrol LED berdasarkan pesan yang diterima
  if (message == "ALL_ON") {
    for (int i = 0; i < 5; i++) {
      digitalWrite(ledPins[i], HIGH); // Nyalakan semua LED
    }
    Serial.println("SEMUA LED MENYALA");
  } else if (message == "ALL_OFF") {
    for (int i = 0; i < 5; i++) {
      digitalWrite(ledPins[i], LOW); // Matikan semua LED
    }
    Serial.println("SEMUA LED MATI");
  } else if (message.startsWith("ON")) {
    int ledNumber = message.substring(2).toInt();
    if (ledNumber >= 1 && ledNumber <= 5) {
      digitalWrite(ledPins[ledNumber - 1], HIGH); // Nyalakan LED tertentu
      Serial.print("LED ");
      Serial.print(ledNumber);
      Serial.println(" MENYALA");
    }
  } else if (message.startsWith("OFF")) {
    int ledNumber = message.substring(3).toInt();
    if (ledNumber >= 1 && ledNumber <= 5) {
      digitalWrite(ledPins[ledNumber - 1], LOW); // Matikan LED tertentu
      Serial.print("LED ");
      Serial.print(ledNumber);
      Serial.println(" MATI");
    }
  }
}

void setup() {
  Serial.begin(115200);
  for (int i = 0; i < 5; i++) {
    pinMode(ledPins[i], OUTPUT); // Setel pin LED sebagai output
    digitalWrite(ledPins[i], LOW); // Pastikan LED mati di awal
  }
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
}

void setup_wifi() {
  delay(10);
  Serial.println();
  Serial.print("Menghubungkan ke ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi tersambung");
  Serial.println("Alamat IP: ");
  Serial.println(WiFi.localIP());
}

void reconnect() {
  // Loop sampai terhubung kembali ke MQTT broker
  while (!client.connected()) {
    Serial.print("Menghubungkan kembali ke MQTT... ");
    // Buat ID unik untuk ESP32
    String clientId = "clientId-HiSNT6bxji";
    clientId += String(random(0xffff), HEX);

    if (client.connect(clientId.c_str())) {
      Serial.println("Tersambung");

      // Subscribe ke topik tertentu
      client.subscribe("esp32/led");
      Serial.println("Berlangganan ke topik: esp32/led");
    } else {
      Serial.print("gagal, rc=");
      Serial.print(client.state());
      Serial.println(" coba lagi dalam 5 detik");
      // Tunggu 5 detik sebelum mencoba lagi
      delay(5000);
    }
  }
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();
}