#include <WiFi.h>
#include <PubSubClient.h>
#include <OneWire.h>
#include <DallasTemperature.h>
#include <ArduinoJson.h>
#include <SimpleTimer.h>
#include "time.h"
#include <FastBot.h>
#include <NTPClient.h>
#include <WiFiUdp.h>

//Internet resources
//https://github.com/GyverLibs/FastBot
//https://mqtt.org/


SimpleTimer timer_ds18b20(2000);
SimpleTimer timer_main(5000);

const char* ssid = "Wokwi-GUEST";
const char* password = "";

const char* mqtt_server = "test.mosquitto.org";
const int mqtt_port = 1884;
const char* mqtt_topic = "TOIP/lab4/boiler/temperature";
const char* mqtt_username = "wo";
const char* mqtt_password = "writeonly";

const char* bot_token = "6780587077:AAGfuAjlpo__OTIEb-kCSRe8dQCd1jEZPis";
const char* chat_id = "460540516";

const int DS18D20_PIN = 12;

unsigned long currentMillis = 0, lastDS18BTime = 0, lastSendDataTime = 0;
float temperature = 0;

FastBot bot(bot_token);

OneWire oneWire(DS18D20_PIN);
DallasTemperature sensors(&oneWire);

WiFiClient espClient;
PubSubClient client(espClient);

WiFiUDP ntpUDP;
NTPClient timeClient(ntpUDP, "pool.ntp.org", 0, 60000); 

void setup_wifi() {
  delay(10);
  Serial.println("Connecting to WiFi...");

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP Address: ");
  Serial.println(WiFi.localIP());
}

void messageParser(FB_msg& msg) {
  if (msg.text == "/get_temp") {
    bot.sendMessage("Current temperature: " + String(temperature));
  }
}

void setup() {
  Serial.begin(115200);

  bot.setChatID(chat_id);
  bot.attach(messageParser);

  setup_wifi();
  client.setServer(mqtt_server, mqtt_port);

  sensors.begin();
  timeClient.begin();
}

void loop() {
  bot.tick();
  if (!client.connected()) {
    reconnect();
  }
  client.loop();
  timeClient.update();

  unsigned long currentMillis = millis();

  if (currentMillis - lastDS18BTime >= 2000) {
    lastDS18BTime = currentMillis;
    sensors.requestTemperatures(); 
    temperature = sensors.getTempCByIndex(0);
  }

  if (currentMillis - lastSendDataTime >= 5000) {
    lastSendDataTime = currentMillis;
    sendTemperature();
  }
}

void sendTemperature() {
  String currentTime = timeClient.getFormattedTime();

  String payload = String(temperature) + " " + currentTime;
  client.publish(mqtt_topic, payload.c_str());
  Serial.println("Temperature: " + String(temperature) + ", time: " + String(currentTime));
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    String clientId = "ESPClient-";
    clientId += String(random(0xffff), HEX);
    if (client.connect(clientId.c_str(), mqtt_username, mqtt_password)) {
      Serial.println("connected");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}