#include <WiFi.h>
#include <PubSubClient.h>

#define ledred 5
#define ledgreen 2
#define ledblue 4

const char* ssid = "Wokwi-GUEST";
const char* password = "";

const char* mqttServer = "broker.hivemq.com";
int mqttPort = 1883;
const char* topicMQTT = "naufel/dhtled";

WiFiClient espClient;
PubSubClient clientMQTT(espClient);

void connectToInternet();
void setupMQTT();
void reconnectMQTT();
void callback(char* topic, byte* message, unsigned int length);
float parseTemperature(String message);
void controlLEDs(float temperature);

void setup() {
    pinMode(ledred, OUTPUT);
    pinMode(ledgreen, OUTPUT);
    pinMode(ledblue, OUTPUT);

    Serial.begin(115200);
    connectToInternet();
    setupMQTT();
    clientMQTT.setCallback(callback);
}

void connectToInternet() {
    Serial.println("Connecting to ");
    Serial.println(ssid);
    WiFi.begin(ssid, password);
    while (WiFi.status() != WL_CONNECTED) {
        delay(200);
        Serial.print(".");
    }
    Serial.println("");
    Serial.println("Connected to WiFi");
    Serial.print("IP Address: ");
    Serial.println(WiFi.localIP());
}

void loop() {
    if (!clientMQTT.connected()) {
        reconnectMQTT();
    }
    clientMQTT.loop();
}

void setupMQTT() {
    clientMQTT.setServer(mqttServer, mqttPort);
}

void reconnectMQTT() {
    while (!clientMQTT.connected()) {
        Serial.println("Reconnecting to MQTT Broker...");
        String clientId = "ESP32Client-";
        clientId += String(random(0xffff), HEX);
        if (clientMQTT.connect(clientId.c_str())) {
            Serial.println("Connected to MQTT Broker");
            clientMQTT.subscribe(topicMQTT);
        } else {
            Serial.print("Failed to connect, rc=");
            Serial.print(clientMQTT.state());
            Serial.println(" try again in 5 seconds");
            delay(5000);
        }
    }
}

void callback(char* topic, byte* message, unsigned int length) {
    Serial.print("Message arrived: ");
    Serial.print(topic);
    String messageTemp;
    for (int i = 0; i < length; i++) {
        messageTemp += (char)message[i];
    }
    Serial.println(" Message: " + messageTemp);

    if (String(topic) == topicMQTT) {
        float temperature = parseTemperature(messageTemp);
        controlLEDs(temperature);
    }
}

float parseTemperature(String message) {
    int startIndex = message.indexOf("Temperature: ") + 13;
    int endIndex = message.indexOf("C");
    String tempString = message.substring(startIndex, endIndex);
    return tempString.toFloat();
}

void controlLEDs(float temperature) {
    if (temperature < 20) {
        digitalWrite(ledred, HIGH);
        digitalWrite(ledgreen, LOW);
        digitalWrite(ledblue, LOW);
        Serial.println("Warning! Temperatur dibawah 20C");
    } else if (temperature > 23) {
        digitalWrite(ledred, LOW);
        digitalWrite(ledgreen, HIGH);
        digitalWrite(ledblue, LOW);
        Serial.println("Danger! Temperatur diatas 23C");
    } else {
        digitalWrite(ledred, LOW);
        digitalWrite(ledgreen, LOW);
        digitalWrite(ledblue, HIGH);
        Serial.println("Normal! Temperatur diantara 20C dan 23C");
    }
}