#include <DHT.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>

// Mendefinisikan variabel
#define DHTPIN 2
#define DHTTYPE DHT22

#define TRIGGER_PIN 3
#define ECHO_PIN 4

#define PHOTOCELL_PIN A0
#define RELAY_PIN 7

// Mendefinisikan pin I2C
#define SDA_PIN 8
#define SCL_PIN 9

DHT dht(DHTPIN, DHTTYPE);
LiquidCrystal_I2C lcd(0x27, 16, 2);

unsigned long previousMillis = 0;
const long interval = 5000; // Interval waktu untuk berganti tampilan (ms)
bool showTempHumid = true;  // Flag untuk menentukan tampilan

void setup() {
  pinMode(TRIGGER_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);
  pinMode(RELAY_PIN, OUTPUT);

  // Inisialisasi komunikasi I2C pada pin SDA dan SCL yang didefinisikan
  Wire.begin(SDA_PIN, SCL_PIN);

  lcd.init();
  lcd.backlight();
  lcd.clear();

  dht.begin();
  Serial.begin(9600);

  // Menampilkan pesan awal di layar LCD
  lcd.setCursor(0, 0);
  lcd.print("Inisialisasi");
  delay(2000);
  lcd.clear();
}

void loop() {
  float temperature = dht.readTemperature();
  float humidity = dht.readHumidity();
  float distance = getDistance();
  int lightValue = analogRead(PHOTOCELL_PIN);

  unsigned long currentMillis = millis();

  if (currentMillis - previousMillis >= interval) {
    previousMillis = currentMillis;
    showTempHumid = !showTempHumid; // Berganti tampilan
  }

  if (showTempHumid) {
    // Menampilkan suhu dan kelembapan
    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("Temp: ");
    lcd.print(temperature);
    lcd.print("C ");
    lcd.setCursor(0, 1);
    lcd.print("Hum: ");
    lcd.print(humidity);
    lcd.print("%");
  } else {
    // Menampilkan jarak dan intensitas cahaya
    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("Dist: ");
    lcd.print(distance);
    lcd.print("cm ");
    lcd.setCursor(0, 1);
    lcd.print("Lgt: ");
    lcd.print(lightValue);
  }

  // Menghidupkan atau mematikan relay berdasarkan nilai dari photoresistor
  if (lightValue > 500) {
    digitalWrite(RELAY_PIN, HIGH);
  } else {
    digitalWrite(RELAY_PIN, LOW);
  }

  // Mencetak nilai sensor ke Serial Monitor
  Serial.print("Temperature: ");
  Serial.print(temperature);
  Serial.print(" C, Humidity: ");
  Serial.print(humidity);
  Serial.print(" %, Distance: ");
  Serial.print(distance);
  Serial.print(" cm, Light: ");
  Serial.println(lightValue);

  delay(200);
}

float getDistance() {
  digitalWrite(TRIGGER_PIN, LOW);
  delayMicroseconds(2);
  digitalWrite(TRIGGER_PIN, HIGH);
  delayMicroseconds(10);
  digitalWrite(TRIGGER_PIN, LOW);
  float duration = pulseIn(ECHO_PIN, HIGH);
  float distance = (duration * 0.034) / 2;
  return distance;
}