#include <WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>

#define DHTPIN  13
#define DHTTYPE DHT22
#define PIR_PIN 12  // Define the GPIO pin for the PIR sensor

DHT dht(DHTPIN, DHTTYPE);

// Update these with values suitable for your network.
const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqtt_server = "public.mqtthq.com"; 
const char* username = "";
const char* pass = "";

char str_hum_data[10];
char str_temp_data[10];

WiFiClient espClient;
PubSubClient client(espClient);
unsigned long lastMsg = 0;
unsigned long lastPirMsg = 0;
#define MSG_BUFFER_SIZE  (50)
char msg[MSG_BUFFER_SIZE];
int value = 0;

#define sub1 "status"
#define PIR_TOPIC "anja/esp32/pir"  // MQTT topic for PIR sensor data

void setup_wifi() {
  delay(10);
  // We start by connecting to a WiFi network
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  randomSeed(micros());

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");

  if (strstr(topic, sub1))  //Button 1
  {
    for (int i = 0; i < length; i++) {
      Serial.print((char)payload[i]);
    }
    Serial.println();
  }
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    String clientId = "ESP8266Client-";
    clientId += String(random(0xffff), HEX);
    // Attempt to connect
    if (client.connect(clientId.c_str(), username, pass) ) {
      Serial.println("connected");
      client.subscribe(sub1);
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}

void setup() {
  Serial.begin(115200);
  Serial.println("Hello, Oby Zamisyak");
  dht.begin();
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);

  pinMode(PIR_PIN, INPUT);  // Initialize the PIR sensor pin as an input
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  unsigned long now = millis();

  if (now - lastMsg > 2000) {
    float hum_data = dht.readHumidity();
    Serial.println(hum_data);
    dtostrf(hum_data, 4, 2, str_hum_data);
    float temp_data = dht.readTemperature(); // or dht.readTemperature(true) for Fahrenheit
    dtostrf(temp_data, 4, 2, str_temp_data);
    lastMsg = now;
    Serial.println("Publish message: ");
    Serial.print("Temperature:  "); Serial.println(str_temp_data);
    client.publish("anja/esp32/temp1", str_temp_data);
    Serial.print("Humidity:  "); Serial.println(str_hum_data);
    client.publish("anja/esp32/hum1", str_hum_data);
  }

  // Read PIR sensor and publish its state
  if (now - lastPirMsg > 1000) {  // Adjust the interval as needed
    int pirState = digitalRead(PIR_PIN);
    Serial.print("PIR state: "); Serial.println(pirState);
    if (pirState == HIGH) {
      client.publish(PIR_TOPIC, "ada pergerakan");
      Serial.println("ada pergerakan");
    } else {
      client.publish(PIR_TOPIC, "tidak ada pergerakan");
      Serial.println("tidak ada pergerakan");
    }
    lastPirMsg = now;
  }
}