#include <WiFi.h>
#include <HTTPClient.h>
#include <DHT.h>

// Ganti dengan SSID dan password WiFi Anda
const char* ssid = "Wokwi-GUEST";
const char* password = "";

// Ganti dengan token akses dari perangkat ThingsBoard Anda
const char* accessToken = "PCLY7xdDyIgUnPDuepXJ";

// URL ThingsBoard, biasanya dalam format: http://<THINGSBOARD_HOST>:<PORT>
const char* server = "http://thingsboard.cloud/api/v1/PCLY7xdDyIgUnPDuepXJ/telemetry";

// Pin data sensor DHT
#define DHTPIN 33
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE);

void setup() {
  Serial.begin(115200);
  dht.begin();

  // Hubungkan ke WiFi
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.println("Connecting to WiFi...");
  }
  Serial.println("Connected to WiFi");
}

void loop() {
  if (WiFi.status() == WL_CONNECTED) {
    HTTPClient http;

    // Baca nilai dari sensor DHT11
    float temperature = dht.readTemperature();
    float humidity = dht.readHumidity();

    if (isnan(temperature) || isnan(humidity)) {
      Serial.println("Failed to read from DHT sensor!");
      return;
    }

    // Tampilkan nilai suhu dan kelembaban di Serial Monitor
    Serial.print("Temperature (raw): ");
    Serial.print(temperature);
    Serial.print(" °C, Humidity (raw): ");
    Serial.print(humidity);
    Serial.println(" %");

    // Buat URL request
    String url = server;

    // Data telemetri dalam format JSON
    String payload = "{\"temperature\": " + String(temperature, 2) + ", \"humidity\": " + String(humidity, 2) + "}";

    // Debugging: tampilkan URL dan payload
    Serial.print("Sending data to: ");
    Serial.println(url);
    Serial.print("Payload: ");
    Serial.println(payload);

    http.begin(url);
    http.addHeader("Content-Type", "application/json");

    // Kirim data telemetri ke ThingsBoard
    int httpResponseCode = http.POST(payload);

    if (httpResponseCode > 0) {
      String response = http.getString();
      Serial.println(httpResponseCode);
      Serial.println(response);
    } else {
      Serial.print("Error on sending POST: ");
      Serial.println(httpResponseCode);
    }

    http.end();
  } else {
    Serial.println("WiFi not connected");
  }

  // Tunggu 10 detik sebelum mengirim data lagi
  delay(1000);
}